net-dns/rbldnsd: new revision with GLEP81 and a fix for python deps.

Standard GLEP81 update in the process of fixing bug 708584, which
looks to need only a single has_version call predicated on USE=test
added in python_check_deps().

Closes: https://bugs.gentoo.org/708584
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

diff --git a/net-dns/rbldnsd/rbldnsd-0.998b-r1.ebuild b/net-dns/rbldnsd/rbldnsd-0.998b-r1.ebuild
new file mode 100644 (file)
index 0000000..c73e294
--- /dev/null
+++ b/net-dns/rbldnsd/rbldnsd-0.998b-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python2_7 )
+
+inherit toolchain-funcs python-any-r1
+
+DESCRIPTION="DNS server designed to serve blacklist zones"
+HOMEPAGE="https://rbldnsd.io/"
+SRC_URI="https://github.com/spamhaus/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~sparc ~x86"
+IUSE="ipv6 test zlib"
+RESTRICT="!test? ( test )"
+
+RDEPEND="zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       acct-group/rbldns
+       acct-user/rbldns
+       test? (
+               ${RDEPEND}
+               ${PYTHON_DEPS}
+               $(python_gen_any_dep 'dev-python/pydns:2[${PYTHON_USEDEP}]')
+       )"
+
+PATCHES=(
+       "${FILESDIR}/rbldnsd-0.997a-robust-ipv6-test-support.patch"
+)
+
+src_configure() {
+       # The ./configure file is handwritten and doesn't support a `make
+       # install` target, so there are no --prefix options. The econf
+       # function appends those automatically, so we can't use it.
+       ./configure \
+               $(use_enable ipv6) \
+               $(use_enable zlib) \
+               || die "./configure failed"
+}
+
+src_compile() {
+       emake \
+               AR="$(tc-getAR)" \
+               CC="$(tc-getCC)" \
+               RANLIB="$(tc-getRANLIB)"
+}
+
+src_test() {
+       emake check \
+               CC="$(tc-getCC)" \
+               PYTHON="${PYTHON}"
+}
+
+src_install() {
+       einstalldocs
+       dosbin rbldnsd
+       doman rbldnsd.8
+       newinitd "${FILESDIR}"/initd-0.997a rbldnsd
+       newconfd "${FILESDIR}"/confd-0.997a rbldnsd
+       diropts -g rbldns -o rbldns -m 0750
+       keepdir /var/db/rbldnsd
+}
+
+python_check_deps() {
+       ! use test || has_version "dev-python/pydns:2[${PYTHON_USEDEP}]"
+}