media-libs/libzen: version bump to 0.4.38

Signed-off-by: Tim Harder <radhermit@gentoo.org>

diff --git a/media-libs/libzen/Manifest b/media-libs/libzen/Manifest
index b31c1b2307d156da379fd10bea33fd2b8b32ef04..571589cba78f924fd5c92b8e57f7caa1c51777d2 100644 (file)
--- a/media-libs/libzen/Manifest
+++ b/media-libs/libzen/Manifest
@@ -1 +1,2 @@
 DIST libzen_0.4.37.tar.bz2 121707 BLAKE2B a9ffb4c06b5cb6dbb4c41f7d0b5293878b58ee842a5983a684f251bddb4c31184b1edc9604edd6e1961920c2341581001da2fd6ed204e6bed7620066ad73f1cc SHA512 3b5bec79470bec054cfa759e753e3925fbd9f27e508c692c0b100fcf1599696bff462d92c08799646e6ffc74c176e7cc7509ae0754c4710d527494f59d95d12b
+DIST libzen_0.4.38.tar.bz2 129706 BLAKE2B 3e40e31663f655885f47b7674936a765cce032da25fcc3f57604b116414bf4348db363a4745bf98126879de9d2de5d4443af1fe3a1f64a7bafd3525eb1ca38da SHA512 d946cd2349848925e13a3fb6aab5ad4f5aca28bc89b3263faca3096d7bbcae3a4ff9ed2552bf005b4ca1f4c8c8f59856f4c4aafa7c734ecebd078e6fc40a9a0b

diff --git a/media-libs/libzen/libzen-0.4.38.ebuild b/media-libs/libzen/libzen-0.4.38.ebuild
new file mode 100644 (file)
index 0000000..8ae68b8
--- /dev/null
+++ b/media-libs/libzen/libzen-0.4.38.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools multilib
+
+MY_PN="ZenLib"
+DESCRIPTION="Shared library for libmediainfo and mediainfo"
+HOMEPAGE="https://github.com/MediaArea/ZenLib"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.bz2"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc static-libs"
+
+DEPEND="virtual/pkgconfig
+       doc? ( app-doc/doxygen )"
+
+S=${WORKDIR}/${MY_PN}/Project/GNU/Library
+
+src_prepare() {
+       default
+       sed -i 's:-O2::' configure.ac || die
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               --enable-unicode \
+               --enable-shared \
+               $(use_enable static-libs static)
+}
+
+src_compile() {
+       default
+
+       if use doc ; then
+               cd "${WORKDIR}"/${MY_PN}/Source/Doc
+               doxygen Doxyfile || die
+       fi
+}
+
+src_install() {
+       default
+
+       # remove since the pkgconfig file should be used instead
+       rm "${D}"/usr/bin/libzen-config
+
+       insinto /usr/$(get_libdir)/pkgconfig
+       doins ${PN}.pc
+
+       for x in ./ Format/Html Format/Http HTTP_Client ; do
+               insinto /usr/include/${MY_PN}/${x}
+               doins "${WORKDIR}"/${MY_PN}/Source/${MY_PN}/${x}/*.h
+       done
+
+       dodoc "${WORKDIR}"/${MY_PN}/History.txt
+       if use doc ; then
+               docinto html
+               dodoc "${WORKDIR}"/${MY_PN}/Doc/*
+       fi
+
+       find "${ED}" -name '*.la' -delete || die
+}