media-gfx/pngquant: Bump to 2.12.6

Package-Manager: Portage-2.3.93, Repoman-2.3.20
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

diff --git a/media-gfx/pngquant/Manifest b/media-gfx/pngquant/Manifest
index 33e8ab22e44596f8a29fe38d593ce4a2ff8268fd..f10201cff3f0ed861268f9ed672b86cb9c8f5e21 100644 (file)
--- a/media-gfx/pngquant/Manifest
+++ b/media-gfx/pngquant/Manifest
@@ -1 +1,2 @@
 DIST pngquant-2.12.3-src.tar.gz 143572 BLAKE2B 6f4cc9f36c9148f36734d9afa3765e206c09e833064cff5d98494d0d71610e857d7c605bc5673eb9fd5b38029ade60c9c1ffc18e745a3dfe5dbde6d39a81d0c7 SHA512 cf39f56750a49b2818fb86b168845e54f3797b664c3f49535ee93a3dc899299192a692039396ffcddc5988d040a778006c5f701f8bcd9f5c73583a47b711b01c
+DIST pngquant-2.12.6.tar.gz 69074 BLAKE2B 3573d54d94b0085de9ffd4dd34a8fd46c49a1e02d0a6419271c17bc7ac7ab6c05d811336a3a8a8ab21d4dea774c93ee1baae141b42c255838fb1eef9cdb1a871 SHA512 8ffff346df67edf1000c71b6d26371826bc4d236b3f57ef1ec73b3b61668cff9c3ca7d541417c39bc6c89e00176c91eb28867b7a91945ac84292ca0ac54984e9

diff --git a/media-gfx/pngquant/pngquant-2.12.6.ebuild b/media-gfx/pngquant/pngquant-2.12.6.ebuild
new file mode 100644 (file)
index 0000000..aa316da
--- /dev/null
+++ b/media-gfx/pngquant/pngquant-2.12.6.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit toolchain-funcs
+
+DESCRIPTION="command-line utility and library for lossy compression of PNG images"
+HOMEPAGE="https://pngquant.org/ https://github.com/kornelski/pngquant"
+SRC_URI="https://github.com/kornelski/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 HPND rwpng"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug lcms openmp cpu_flags_x86_sse2"
+
+RDEPEND="media-libs/libpng:0=
+       media-gfx/libimagequant:=
+       sys-libs/zlib:=
+       lcms? ( media-libs/lcms:2 )"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.12.2-respect-CFLAGS.patch )
+
+src_prepare() {
+       default
+
+       # avoid silent fallback to bundled lib
+       rm -rv lib || die
+}
+
+src_configure() {
+       tc-export AR CC
+       # Hand rolled configure script, so not all flags are supported.
+       ./configure \
+               --prefix="${EPREFIX}/usr" \
+               --with-libimagequant \
+               $(use debug && echo --enable-debug) \
+               $(use_enable cpu_flags_x86_sse2 sse) \
+               $(use openmp && tc-has-openmp && echo --with-openmp) \
+               $(use_with lcms lcms2) \
+               CFLAGS="${CFLAGS} ${CPPFLAGS}" \
+               LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+       dobin ${PN}
+       doman ${PN}.1
+       dodoc CHANGELOG README.md
+}