dev-util/debugedit: Bump to 4.15.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/dev-util/debugedit/Manifest b/dev-util/debugedit/Manifest
index a4ea0f4debd26aa67c0d5aced0762d05fb24e208..c7fc2f6be3248623e604c3162af41658333418ae 100644 (file)
--- a/dev-util/debugedit/Manifest
+++ b/dev-util/debugedit/Manifest
@@ -1 +1,2 @@
 DIST rpm-4.15.0.tar.bz2 4205632 BLAKE2B 3e9701582e82d4164a21374df78c7a9ab3ca4f9aeafc13706fd0aa27782a34d2a732d7ae9659589abc9f9b8a48ce5c2cdbbea72c46768f1baba28ded26817e5b SHA512 bca9cc9ef0ad53fa5cd257c29a0a0b9447956afe4024835f5416b13926bc8bbaf8aacd481e721b4a28983bc57f98b75b91750d39dd72de4876efa9d6db53a26c
+DIST rpm-4.15.1.tar.bz2 4243893 BLAKE2B 352695e1fdac231127c9a2a775ff1aa05c1f3acbb10b0678e06011f9e4a5124e48cc19dce83417866e0f3c92bfd94e9c52b8c1884151ee77559bea1020d3623e SHA512 6c66835da5a54349bcfba5cc69831c8c57568aabd53c5c2820ec78c361be5116fecd41777b097e9c49458f984a7beb054fa8ed453ff7263cad4a29a11f780767

diff --git a/dev-util/debugedit/debugedit-4.15.1.ebuild b/dev-util/debugedit/debugedit-4.15.1.ebuild
new file mode 100644 (file)
index 0000000..dac8e1b
--- /dev/null
+++ b/dev-util/debugedit/debugedit-4.15.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic
+
+MY_P=rpm-${PV}
+DESCRIPTION="Stand-alone debugedit from RPM"
+HOMEPAGE="https://rpm.org
+       https://github.com/rpm-software-management/rpm"
+SRC_URI="http://ftp.rpm.org/releases/rpm-$(ver_cut 1-2).x/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+       sys-libs/zlib:=
+       >=dev-libs/popt-1.7
+       >=dev-libs/elfutils-0.176-r1
+       dev-libs/nss
+"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig
+"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+       eapply_user
+
+       # cheat it into believing we're bundling db
+       mkdir -p db/dist || die
+       touch db/dist/configure || die
+       chmod +x db/dist/configure || die
+       echo 'install:' > db3/Makefile || die
+
+       # TODO: why do we need to do this?
+       mkdir rpm || die
+       find -name '*.h' -exec cp {} rpm/ ';' || die
+}
+
+src_configure() {
+       append-cppflags -I"${EPREFIX}/usr/include/nss" -I"${EPREFIX}/usr/include/nspr"
+       local myconf=(
+               # force linking to static librpmio
+               --disable-shared
+
+               # disable linking compression libraries
+               ac_cv_header_bzlib_h=no
+               ac_cv_header_lzma_h=no
+               --disable-zstd
+
+               # fake some libraries we don't use
+               ac_cv_header_magic_h=yes
+               ac_cv_lib_magic_magic_open=yes
+
+               # use nss as crypto provider
+               --with-crypto=nss
+
+               # disable other stuff irrelevant to debugedit
+               --disable-bdb
+               --disable-nls
+               --disable-plugins
+               --disable-python
+               --without-acl
+               --without-archive
+               --without-cap
+               --without-external-db
+               --without-hackingdocs
+               --without-lua
+               --without-selinux
+       )
+       econf "${myconf[@]}"
+}
+
+src_compile() {
+       emake -C misc
+       emake -C rpmio
+       emake debugedit
+}
+
+src_test() {
+       :
+}
+
+src_install() {
+       dobin debugedit
+}