app-crypt/xca: Bump to 2.2.1

Signed-off-by: Mike Auty <ikelos@gentoo.org>

diff --git a/app-crypt/xca/Manifest b/app-crypt/xca/Manifest
index 43fb629c55533ca3334e57d6cda66b2ef9981f7e..84a6b9d851e8e4aba84c65743e0a06424bbfdf17 100644 (file)
--- a/app-crypt/xca/Manifest
+++ b/app-crypt/xca/Manifest
@@ -1 +1,2 @@
 DIST xca-2.1.2.tar.gz 1086563 BLAKE2B d48727fffad16d840633af6e0ee38a279978a5b865eb6f391a3d852a0105817254ea0a4780875f2956e1f7e9931e6930c6ffbe82b117dbf8ad0058ec9d6f5c88 SHA512 1f104a22b83b802576b4820b7139971da50f9b3dd70aca8e1199e996bad4379b8681bb31b197b84a3dfa49cef4ae093f6622d15fac9667547ff47af43c1e5f07
+DIST xca-2.2.1.tar.gz 1339412 BLAKE2B 5d3e33a711919d85bc3457ddd596f2272f0136d96290aeb31e6d03ea86faff00be3590862e4c96d9214542db1bd536d0d22c6c04cd5071b253bbefe3ab3f4f56 SHA512 90eaf4a859779d57a4c0201dc403d67e005bd540145b9f543e13b8d5c42199f2ea05543de24b071d19a0db8e5b1e9f3bef2aea4bfe9f71f81007a5f5bb3ba406

diff --git a/app-crypt/xca/xca-2.2.1.ebuild b/app-crypt/xca/xca-2.2.1.ebuild
new file mode 100644 (file)
index 0000000..e8d94c2
--- /dev/null
+++ b/app-crypt/xca/xca-2.2.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+inherit xdg-utils
+
+DESCRIPTION="A GUI to OpenSSL, RSA public keys, certificates, signing requests etc"
+HOMEPAGE="https://hohnstaedt.de/xca/"
+SRC_URI="https://github.com/chris2511/${PN}/releases/download/RELEASE.${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="bindist doc libressl"
+
+RDEPEND="
+       dev-libs/libltdl:0=
+       dev-qt/qtgui:5
+       dev-qt/qtsql:5[sqlite]
+       dev-qt/qtwidgets:5
+       !libressl? ( dev-libs/openssl:0=[bindist=] )
+       libressl? ( >=dev-libs/libressl-2.7.0:0= )
+       doc? ( app-text/linuxdoc-tools )"
+DEPEND="${RDEPEND}
+       dev-qt/linguist-tools:5"
+
+PATCHES=(
+       "${FILESDIR}/${PN}-1.0.0-desktop.patch"
+)
+
+src_configure() {
+       econf \
+               --with-qt-version=5 \
+               $(use_enable doc) \
+               STRIP=true
+}
+
+src_compile() {
+       # enforce all to avoid the automatic silent rules
+       emake all
+}
+
+src_install() {
+       # non standard destdir
+       emake install destdir="${ED}"
+       einstalldocs
+
+       insinto /etc/xca
+       doins misc/*.txt
+
+       ewarn "Make a backup copy of your database!"
+       ewarn "Version 2 completely changes the database format to SQL(ite)"
+       ewarn "Don't try to open it with older versions of XCA (< 1.4.0). They will corrupt the database."
+}
+
+pkg_postinst() {
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+       xdg_desktop_database_update
+       xdg_mimeinfo_database_update
+}