net-libs/srt: EAPI-7 bump, missing slot op, missing $MULTILIB_USEDEP

Drop unused USE doc.

Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/net-libs/srt/srt-1.3.1-r1.ebuild b/net-libs/srt/srt-1.3.1-r1.ebuild
new file mode 100644 (file)
index 0000000..c528409
--- /dev/null
+++ b/net-libs/srt/srt-1.3.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-multilib
+
+DESCRIPTION="Open-source implementation of the Secure Real-time Transport Protocol (SRTP)"
+HOMEPAGE="https://github.com/Haivision/srt"
+
+if [[ ${PV} == *9999 ]] ; then
+       EGIT_REPO_URI="https://github.com/Haivision/${PN}.git"
+       inherit git-r3
+else
+       SRC_URI="https://github.com/Haivision/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 -sparc ~x86 ~x86-fbsd ~ppc-macos ~x64-macos ~x86-macos"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="gnutls libressl"
+
+DEPEND="
+       gnutls? ( net-libs/gnutls:=[${MULTILIB_USEDEP}] )
+       !gnutls? (
+               !libressl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
+               libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
+       )
+"
+RDEPEND="${DEPEND}"
+
+DOCS=( README.md )
+
+PATCHES=(
+       "${FILESDIR}/${PN}-always-GNUInstallDirs.patch"
+       "${FILESDIR}/${P}-no-rpath.patch"
+       "${FILESDIR}/${P}-use-destdir-for-symlinks-09afc227e0880b12a98e18ee8182f89c3a80e3a6.patch"
+)
+
+src_prepare() {
+       cmake-utils_src_prepare
+       sed -i -e "s:hcrypt_ut.c::" "${S}"/haicrypt/*.maf || die
+       sed -i -e 's:DESTINATION lib:DESTINATION lib${LIB_SUFFIX}:' CMakeLists.txt || die
+}
+
+src_configure() {
+       local mycmakeargs=(
+               -DUSE_GNUTLS=$(usex gnutls)
+       )
+       cmake-multilib_src_configure
+}

diff --git a/net-libs/srt/srt-9999.ebuild b/net-libs/srt/srt-9999.ebuild
index 6ba9d8717793a2312333aadbbc13fc93e42246eb..7cdc3dc723e84941a0dd84cfddfed94aded78fcb 100644 (file)
--- a/net-libs/srt/srt-9999.ebuild
+++ b/net-libs/srt/srt-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2018 Gentoo Authors
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 inherit cmake-multilib
 
@@ -18,18 +18,22 @@ fi
 
 LICENSE="LGPL-2.1"
 SLOT="0"
-IUSE="doc libressl gnutls test"
+IUSE="gnutls libressl test"
 
-RDEPEND="
-       gnutls? ( net-libs/gnutls )
+BDEPEND="
+       test? ( dev-cpp/gtest )
+"
+DEPEND="
+       gnutls? ( net-libs/gnutls:=[${MULTILIB_USEDEP}] )
        !gnutls? (
                !libressl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
                libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
        )
 "
-DEPEND="${RDEPEND}
-       test? ( dev-cpp/gtest )"
+RDEPEND="${DEPEND}"
+
 RESTRICT="!test? ( test )"
+
 DOCS=( README.md )
 
 PATCHES=(