dev-util/clazy: 1.6 version bump

Closes: https://bugs.gentoo.org/714044
Package-Manager: Portage-2.3.96, Repoman-2.3.21
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/dev-util/clazy/Manifest b/dev-util/clazy/Manifest
index f331d9565a13204e867bc1108c080b3a28727b69..3a2f8b7277a23f07a12279e0edaafafcd6283795 100644 (file)
--- a/dev-util/clazy/Manifest
+++ b/dev-util/clazy/Manifest
@@ -1 +1,2 @@
 DIST clazy-1.5.tar.xz 352344 BLAKE2B 0f7200900f1a8bcad3020cf98522e3ac9ba01dddc9b2200f08a8a86102e4389af7a4a86e1832ee4c0e750267948a908627032385a01af94d8d0ae5f438114b9e SHA512 863cb9609d02a2260b61bc6cb3e6d8a84975d3b4e4f1c94a82e8c600d95a28483c323f47ac39c39ecef24d0f51871b358055868c63a49b136cf8ee3060df5a52
+DIST clazy-1.6.tar.xz 364292 BLAKE2B 01da58e34d5a7cb1e812d10264cebe15e90369589535e07f2c9f4520971f2e95b2c70494e99e34f7077957ec1bf01352fa6a72a64f0572e8a5db422267ab727a SHA512 dc7cb9590bbc40a2ac51abe305b6520ebc1ff7128ff21b4f6111d18f14eb8c2ab66d907636a18c7508143b708e70ba69f9d6fad88ffce12dec981a9bdd0edcc0

diff --git a/dev-util/clazy/clazy-1.6.ebuild b/dev-util/clazy/clazy-1.6.ebuild
new file mode 100644 (file)
index 0000000..47f5433
--- /dev/null
+++ b/dev-util/clazy/clazy-1.6.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Compiler plugin which allows clang to understand Qt semantics"
+HOMEPAGE="https://cgit.kde.org/clazy.git/tree/README.md"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.xz"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+RDEPEND="
+       <sys-devel/clang-10:=
+       >=sys-devel/llvm-3.8:=
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( README.md )
+
+src_prepare() {
+       cmake_src_prepare
+
+       sed -e '/install(FILES README.md COPYING-LGPL2.txt checks.json DESTINATION/d' \
+               -i CMakeLists.txt || die
+
+       sed -e 's|${MAN_INSTALL_DIR}|share/man/man1|' \
+               -i docs/man/CMakeLists.txt || die
+}
+
+src_configure() {
+       # this package requires both llvm and clang of the same version.
+       # clang pulls in the equivalent llvm version, but not vice versa.
+       # so, we must find llvm based on the installed clang version.
+       # bug #681568
+       local clang_version=$(best_version "<sys-devel/clang-10")
+       export LLVM_ROOT="/usr/lib/llvm/$(ver_cut 1 ${clang_version##sys-devel/clang-})"
+       cmake_src_configure
+}
+
+src_install() {
+       cmake_src_install
+       mv "${D}"/usr/share/doc/clazy/* "${D}"/usr/share/doc/${PF} || die
+       rmdir "${D}"/usr/share/doc/clazy || die
+}