sys-devel/automake: Bump to EAPI=6 and sync with -9999

Package-Manager: Portage-2.3.6, Repoman-2.3.2
Closes: #4964

diff --git a/sys-devel/automake/automake-1.15.1-r1.ebuild b/sys-devel/automake/automake-1.15.1-r1.ebuild
new file mode 100644 (file)
index 0000000..5051ee0
--- /dev/null
+++ b/sys-devel/automake/automake-1.15.1-r1.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit eutils versionator
+
+if [[ ${PV} == 9999 ]] ; then
+       EGIT_REPO_URI="git://git.savannah.gnu.org/${PN}.git
+               http://git.savannah.gnu.org/r/${PN}.git"
+
+       inherit git-r3
+else
+       KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+       if [[ ${PV/_beta} == ${PV} ]]; then
+               MY_P=${P}
+               SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
+                       ftp://alpha.gnu.org/pub/gnu/${PN}/${MY_P}.tar.xz"
+       else
+               MY_PV="$(get_major_version).$(($(get_version_component_range 2)-1))b"
+               MY_P="${PN}-${MY_PV}"
+
+               # Alpha/beta releases are not distributed on the usual mirrors.
+               SRC_URI="ftp://alpha.gnu.org/pub/gnu/${PN}/${MY_P}.tar.xz"
+       fi
+       S="${WORKDIR}/${MY_P}"
+fi
+
+DESCRIPTION="Used to generate Makefile.in from Makefile.am"
+HOMEPAGE="https://www.gnu.org/software/automake/"
+
+LICENSE="GPL-2"
+# Use Gentoo versioning for slotting.
+SLOT="${PV:0:4}"
+IUSE=""
+
+RDEPEND="dev-lang/perl
+       >=sys-devel/automake-wrapper-10
+       >=sys-devel/autoconf-2.69:*
+       sys-devel/gnuconfig"
+DEPEND="${RDEPEND}
+       sys-apps/help2man"
+
+src_prepare() {
+       default
+       export WANT_AUTOCONF=2.5
+       # Don't try wrapping the autotools this thing runs as it tends
+       # to be a bit esoteric, and the script does `set -e` itself.
+       ./bootstrap || die
+       sed -i -e "/APIVERSION=/s:=.*:=${SLOT}:" configure || die
+}
+
+# slot the info pages.  do this w/out munging the source so we don't have
+# to depend on texinfo to regen things.  #464146 (among others)
+slot_info_pages() {
+       pushd "${ED}"/usr/share/info >/dev/null || die
+       rm -f dir || dir
+
+       # Rewrite all the references to other pages.
+       # before: * aclocal-invocation: (automake)aclocal Invocation.   Generating aclocal.m4.
+       # after:  * aclocal-invocation v1.13: (automake-1.13)aclocal Invocation.   Generating aclocal.m4.
+       local p pages=( *.info ) args=()
+       for p in "${pages[@]/%.info}" ; do
+               args+=(
+                       -e "/START-INFO-DIR-ENTRY/,/END-INFO-DIR-ENTRY/s|: (${p})| v${SLOT}&|"
+                       -e "s:(${p}):(${p}-${SLOT}):g"
+               )
+       done
+       sed -i "${args[@]}" * || die
+
+       # Rewrite all the file references, and rename them in the process.
+       local f d
+       for f in * ; do
+               d=${f/.info/-${SLOT}.info}
+               mv "${f}" "${d}" || die
+               sed -i -e "s:${f}:${d}:g" * || die
+       done
+
+       popd >/dev/null || die
+}
+
+src_install() {
+       default
+
+       slot_info_pages
+       rm "${ED}"/usr/share/aclocal/README || die
+       rmdir "${ED}"/usr/share/aclocal || die
+       rm \
+               "${ED}"/usr/bin/{aclocal,automake} \
+               "${ED}"/usr/share/man/man1/{aclocal,automake}.1 || die
+
+       # remove all config.guess and config.sub files replacing them
+       # w/a symlink to a specific gnuconfig version
+       local x
+       for x in guess sub ; do
+               dosym ../gnuconfig/config.${x} /usr/share/${PN}-${SLOT}/config.${x}
+       done
+}

diff --git a/sys-devel/automake/automake-9999.ebuild b/sys-devel/automake/automake-9999.ebuild
index cf28ba4edf60ecc6c70af76a3382ed2ded1fcd96..5051ee0ba2c4d6b26d298b71a976e0f5fe6454a4 100644 (file)
--- a/sys-devel/automake/automake-9999.ebuild
+++ b/sys-devel/automake/automake-9999.ebuild
@@ -1,51 +1,60 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="4"
+EAPI="6"
 
-EGIT_REPO_URI="git://git.savannah.gnu.org/${PN}.git
-       http://git.savannah.gnu.org/r/${PN}.git"
+inherit eutils versionator
 
-inherit eutils git-2
+if [[ ${PV} == 9999 ]] ; then
+       EGIT_REPO_URI="git://git.savannah.gnu.org/${PN}.git
+               http://git.savannah.gnu.org/r/${PN}.git"
+
+       inherit git-r3
+else
+       KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+       if [[ ${PV/_beta} == ${PV} ]]; then
+               MY_P=${P}
+               SRC_URI="mirror://gnu/${PN}/${P}.tar.xz
+                       ftp://alpha.gnu.org/pub/gnu/${PN}/${MY_P}.tar.xz"
+       else
+               MY_PV="$(get_major_version).$(($(get_version_component_range 2)-1))b"
+               MY_P="${PN}-${MY_PV}"
+
+               # Alpha/beta releases are not distributed on the usual mirrors.
+               SRC_URI="ftp://alpha.gnu.org/pub/gnu/${PN}/${MY_P}.tar.xz"
+       fi
+       S="${WORKDIR}/${MY_P}"
+fi
 
 DESCRIPTION="Used to generate Makefile.in from Makefile.am"
 HOMEPAGE="https://www.gnu.org/software/automake/"
-SRC_URI=""
 
 LICENSE="GPL-2"
 # Use Gentoo versioning for slotting.
 SLOT="${PV:0:4}"
-KEYWORDS=""
 IUSE=""
 
 RDEPEND="dev-lang/perl
        >=sys-devel/automake-wrapper-10
-       >=sys-devel/autoconf-2.69
-       >=sys-apps/texinfo-4.7
+       >=sys-devel/autoconf-2.69:*
        sys-devel/gnuconfig"
 DEPEND="${RDEPEND}
        sys-apps/help2man"
 
 src_prepare() {
+       default
        export WANT_AUTOCONF=2.5
        # Don't try wrapping the autotools this thing runs as it tends
        # to be a bit esoteric, and the script does `set -e` itself.
-       ./bootstrap.sh
-}
-
-src_configure() {
-       econf --docdir="\$(datarootdir)/doc/${PF}"
-}
-
-src_test() {
-       emake check
+       ./bootstrap || die
+       sed -i -e "/APIVERSION=/s:=.*:=${SLOT}:" configure || die
 }
 
 # slot the info pages.  do this w/out munging the source so we don't have
 # to depend on texinfo to regen things.  #464146 (among others)
 slot_info_pages() {
-       pushd "${ED}"/usr/share/info >/dev/null
-       rm -f dir
+       pushd "${ED}"/usr/share/info >/dev/null || die
+       rm -f dir || dir
 
        # Rewrite all the references to other pages.
        # before: * aclocal-invocation: (automake)aclocal Invocation.   Generating aclocal.m4.
@@ -67,23 +76,22 @@ slot_info_pages() {
                sed -i -e "s:${f}:${d}:g" * || die
        done
 
-       popd >/dev/null
+       popd >/dev/null || die
 }
 
 src_install() {
        default
-       slot_info_pages
 
-       # SLOT the docs and junk
-       local x
-       for x in aclocal automake ; do
-               help2man "perl -Ilib ${x}" > ${x}-${SLOT}.1
-               doman ${x}-${SLOT}.1
-               rm -f "${ED}"/usr/bin/${x}
-       done
+       slot_info_pages
+       rm "${ED}"/usr/share/aclocal/README || die
+       rmdir "${ED}"/usr/share/aclocal || die
+       rm \
+               "${ED}"/usr/bin/{aclocal,automake} \
+               "${ED}"/usr/share/man/man1/{aclocal,automake}.1 || die
 
        # remove all config.guess and config.sub files replacing them
        # w/a symlink to a specific gnuconfig version
+       local x
        for x in guess sub ; do
                dosym ../gnuconfig/config.${x} /usr/share/${PN}-${SLOT}/config.${x}
        done