net-analyzer/netdata: Make xen and cups plugins optional

Closes: https://bugs.gentoo.org/683838
Package-Manager: Portage-2.3.64, Repoman-2.3.12
Signed-off-by: Craig Andrews <candrews@gentoo.org>

diff --git a/net-analyzer/netdata/metadata.xml b/net-analyzer/netdata/metadata.xml
index 04af360a6e2acd9e14641d63b7cb78b295523ef1..06a8ae53618adaf27af51bb01983773830232df1 100644 (file)
--- a/net-analyzer/netdata/metadata.xml
+++ b/net-analyzer/netdata/metadata.xml
@@ -11,6 +11,7 @@
         <flag name="nfacct">Enable the nfacct plugin</flag>
         <flag name="nodejs">Enable use of nodejs (which some plugins use)</flag>
         <flag name="tor">Enable monitoring of tor</flag>
+        <flag name="xen">Enable monitoring of xen</flag>
     </use>
     <upstream>
         <remote-id type="github">netdata/netdata</remote-id>

diff --git a/net-analyzer/netdata/netdata-1.14.0-r1.ebuild b/net-analyzer/netdata/netdata-1.14.0-r1.ebuild
new file mode 100644 (file)
index 0000000..54d1509
--- /dev/null
+++ b/net-analyzer/netdata/netdata-1.14.0-r1.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit autotools fcaps linux-info python-r1 systemd user
+
+if [[ ${PV} == *9999 ]] ; then
+       EGIT_REPO_URI="https://github.com/netdata/${PN}.git"
+       inherit git-r3
+else
+       SRC_URI="https://github.com/netdata/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+       KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Linux real time system monitoring, done right!"
+HOMEPAGE="https://github.com/netdata/netdata https://my-netdata.io/"
+
+LICENSE="GPL-3+ MIT BSD"
+SLOT="0"
+IUSE="caps +compression cpu_flags_x86_sse2 cups ipmi mysql nfacct nodejs postgres +python tor xen"
+REQUIRED_USE="
+       mysql? ( python )
+       python? ( ${PYTHON_REQUIRED_USE} )
+       tor? ( python )"
+
+# most unconditional dependencies are for plugins.d/charts.d.plugin:
+RDEPEND="
+       app-misc/jq
+       >=app-shells/bash-4:0
+       || (
+               net-analyzer/openbsd-netcat
+               net-analyzer/netcat
+       )
+       net-analyzer/tcpdump
+       net-analyzer/traceroute
+       net-misc/curl
+       net-misc/wget
+       sys-apps/util-linux
+       virtual/awk
+       caps? ( sys-libs/libcap )
+       cups? ( net-print/cups )
+       compression? ( sys-libs/zlib )
+       ipmi? ( sys-libs/freeipmi )
+       nfacct? (
+               net-firewall/nfacct
+               net-libs/libmnl
+       )
+       nodejs? ( net-libs/nodejs )
+       python? (
+               ${PYTHON_DEPS}
+               dev-python/pyyaml[${PYTHON_USEDEP}]
+               mysql? (
+                       || (
+                               dev-python/mysqlclient[${PYTHON_USEDEP}]
+                               dev-python/mysql-python[${PYTHON_USEDEP}]
+                       )
+               )
+               postgres? ( dev-python/psycopg:2[${PYTHON_USEDEP}] )
+               tor? ( net-libs/stem[${PYTHON_USEDEP}] )
+       )
+       xen? (
+               app-emulation/xen-tools
+               dev-libs/yajl
+       )"
+DEPEND="${RDEPEND}
+       virtual/pkgconfig"
+
+: ${NETDATA_USER:=netdata}
+: ${NETDATA_GROUP:=netdata}
+
+FILECAPS=(
+       'cap_dac_read_search,cap_sys_ptrace+ep' 'usr/libexec/netdata/plugins.d/apps.plugin'
+)
+
+pkg_setup() {
+       linux-info_pkg_setup
+
+       enewgroup ${PN}
+       enewuser ${PN} -1 -1 / ${PN}
+}
+
+src_prepare() {
+       default
+       eautoreconf
+}
+
+src_configure() {
+       econf \
+               --localstatedir="${EPREFIX}"/var \
+               --with-user=${NETDATA_USER} \
+               $(use_enable cups plugin-cups) \
+               $(use_enable nfacct plugin-nfacct) \
+               $(use_enable ipmi plugin-freeipmi) \
+               $(use_enable xen plugin-xenstat) \
+               $(use_enable cpu_flags_x86_sse2 x86-sse) \
+               $(use_with compression zlib)
+}
+
+src_install() {
+       default
+
+       rm -rf "${D}/var/cache" || die
+
+       # Remove unneeded .keep files
+       find "${ED}" -name ".keep" -delete || die
+
+       fowners -Rc ${NETDATA_USER}:${NETDATA_GROUP} /var/log/netdata
+       keepdir /var/log/netdata
+       fowners -Rc ${NETDATA_USER}:${NETDATA_GROUP} /var/lib/netdata
+       keepdir /var/lib/netdata
+       keepdir /var/lib/netdata/registry
+
+       fowners -Rc root:${NETDATA_GROUP} /usr/share/${PN}
+
+       newinitd system/netdata-openrc ${PN}
+       systemd_dounit system/netdata.service
+       insinto /etc/netdata
+       doins system/netdata.conf
+}

diff --git a/net-analyzer/netdata/netdata-9999.ebuild b/net-analyzer/netdata/netdata-9999.ebuild
index 59396a96cc0e0a542f70a84c23d49fe45aa83d99..54d150969d3c56e60a83049c5f304a06dd491bb7 100644 (file)
--- a/net-analyzer/netdata/netdata-9999.ebuild
+++ b/net-analyzer/netdata/netdata-9999.ebuild
@@ -19,7 +19,7 @@ HOMEPAGE="https://github.com/netdata/netdata https://my-netdata.io/"
 
 LICENSE="GPL-3+ MIT BSD"
 SLOT="0"
-IUSE="caps +compression cpu_flags_x86_sse2 ipmi mysql nfacct nodejs postgres +python tor"
+IUSE="caps +compression cpu_flags_x86_sse2 cups ipmi mysql nfacct nodejs postgres +python tor xen"
 REQUIRED_USE="
        mysql? ( python )
        python? ( ${PYTHON_REQUIRED_USE} )
@@ -40,6 +40,7 @@ RDEPEND="
        sys-apps/util-linux
        virtual/awk
        caps? ( sys-libs/libcap )
+       cups? ( net-print/cups )
        compression? ( sys-libs/zlib )
        ipmi? ( sys-libs/freeipmi )
        nfacct? (
@@ -58,6 +59,10 @@ RDEPEND="
                )
                postgres? ( dev-python/psycopg:2[${PYTHON_USEDEP}] )
                tor? ( net-libs/stem[${PYTHON_USEDEP}] )
+       )
+       xen? (
+               app-emulation/xen-tools
+               dev-libs/yajl
        )"
 DEPEND="${RDEPEND}
        virtual/pkgconfig"
@@ -85,8 +90,10 @@ src_configure() {
        econf \
                --localstatedir="${EPREFIX}"/var \
                --with-user=${NETDATA_USER} \
+               $(use_enable cups plugin-cups) \
                $(use_enable nfacct plugin-nfacct) \
                $(use_enable ipmi plugin-freeipmi) \
+               $(use_enable xen plugin-xenstat) \
                $(use_enable cpu_flags_x86_sse2 x86-sse) \
                $(use_with compression zlib)
 }