net-analyzer/nagios-icinga-openvpn: new revision for newer pythons.

Also with an EAPI=7 update. Nothing else changed.

Closes: https://bugs.gentoo.org/718422
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Michael Orlitzky <mjo@gentoo.org>

diff --git a/net-analyzer/nagios-icinga-openvpn/nagios-icinga-openvpn-0.0.1-r1.ebuild b/net-analyzer/nagios-icinga-openvpn/nagios-icinga-openvpn-0.0.1-r1.ebuild
new file mode 100644 (file)
index 0000000..a03ce2d
--- /dev/null
+++ b/net-analyzer/nagios-icinga-openvpn/nagios-icinga-openvpn-0.0.1-r1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_6 python3_7 python3_8 )
+DISTUTILS_USE_SETUPTOOLS=no
+inherit distutils-r1
+
+MY_PN="check_openvpn"
+DESCRIPTION="A Nagios plugin to check whether an OpenVPN server is alive"
+HOMEPAGE="https://github.com/liquidat/nagios-icinga-openvpn"
+SRC_URI="https://github.com/liquidat/nagios-icinga-openvpn/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+src_install() {
+       distutils-r1_src_install
+
+       local nagiosplugindir="/usr/$(get_libdir)/nagios/plugins"
+       dodir "${nagiosplugindir}"
+
+       # Create a symlink from the nagios plugin directory to the /usr/bin
+       # location. The "binary" in /usr/bin should also be a symlink, since
+       # the python machinery allows the user to switch out the
+       # interpreter. We don't want to mess with any of that, so we just
+       # point to whatever the system would use if the user executed
+       # ${MY_PN}.
+       #
+       # The relative symlink is preferred so that if the package is
+       # installed e.g. while in a chroot, the symlink will never point
+       # outside of that chroot.
+       #
+       dosym "../../../bin/${MY_PN}" "${nagiosplugindir}/${MY_PN}"
+}