media-libs/waffle: Version bump to 1.6.1

Signed-off-by: Matt Turner <mattst88@gentoo.org>

diff --git a/media-libs/waffle/Manifest b/media-libs/waffle/Manifest
index 0b0146e39dc5aa40fc7a44d4d36a7d74bbb9aba1..514148b1a6d9b8dde64697cc2ef3072c3f49737f 100644 (file)
--- a/media-libs/waffle/Manifest
+++ b/media-libs/waffle/Manifest
@@ -1 +1,2 @@
 DIST waffle-1.6.0.tar.xz 224400 BLAKE2B 458add99b346bd75dc757243b9e7db6ac269fb2c1e488333d921c640e10efd182e51e8a5e0312d334593033936adf047fc2339d21e675654d89d66edfb8922b3 SHA512 c8796ab8adf968df2c5c88e2941c83955fe41e87eb2b75b6a5cc61b0d0c06eaa44df2f255f573a51816036dc8bc3ec63f3fb51ccfb7efbfe83cdd50b3f1be13f
+DIST waffle-1.6.1.tar.xz 227152 BLAKE2B 360782636809fa3716589e5c3f2d365ce2a916f3da4dde7ec271ce7e142f94160388f9ae12f1ef0ea79890f45eba9d6ef536e12861ee44cbd88282e3c4f01f52 SHA512 1d5839d517d1067efea163ffd76c05f32f30c3ef0f42dfa1b3a9830d4377829cce368d28889ec5a3be639a5e81db2fb4833d98eafc5ffa5e27578ff11977258f

diff --git a/media-libs/waffle/waffle-1.6.1.ebuild b/media-libs/waffle/waffle-1.6.1.ebuild
new file mode 100644 (file)
index 0000000..b508b01
--- /dev/null
+++ b/media-libs/waffle/waffle-1.6.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]]; then
+       EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/${PN}"
+       GIT_ECLASS="git-r3"
+else
+       SRC_URI="https://gitlab.freedesktop.org/mesa/${PN}/-/raw/website/files/release/${P}/${P}.tar.xz"
+       KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+fi
+inherit meson multilib-minimal ${GIT_ECLASS}
+
+DESCRIPTION="Library that allows selection of GL API and of window system at runtime"
+HOMEPAGE="http://www.waffle-gl.org/ https://gitlab.freedesktop.org/mesa/waffle"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="doc +egl +gbm wayland X"
+RESTRICT="test" # gl_basic tests don't work when run from portage
+
+RDEPEND="
+       >=media-libs/mesa-9.1.6[egl?,gbm?,${MULTILIB_USEDEP}]
+       >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+       >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+       >=x11-libs/libxcb-1.9.1[${MULTILIB_USEDEP}]
+       gbm? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
+       wayland? ( >=dev-libs/wayland-1.10[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+       >=x11-base/xcb-proto-1.8-r3[${MULTILIB_USEDEP}]
+"
+BDEPEND="
+       dev-libs/libxslt
+       app-text/docbook-xml-dtd:4.2
+"
+
+MULTILIB_CHOST_TOOLS=(
+       /usr/bin/wflinfo$(get_exeext)
+)
+
+multilib_src_configure() {
+       local emesonargs=(
+               $(meson_feature X glx)
+               $(meson_feature wayland)
+               $(meson_feature X x11_egl)
+               $(meson_feature gbm)
+               $(meson_feature egl surfaceless_egl)
+               -Dbuild-manpages=true
+               -Dbuild-tests=false
+       )
+       meson_src_configure
+}
+
+multilib_src_compile() {
+       meson_src_compile
+}
+
+multilib_src_install() {
+       meson_src_install
+
+       ! use doc && rm -rf "${D}"/usr/share/doc/waffle1
+}