media-sound/gnome-music: bump to 3.32.2, allow py3.7

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/media-sound/gnome-music/Manifest b/media-sound/gnome-music/Manifest
index 8f1734ee64b4c7e4cc862a1580eb12f6707affb8..58eb5d5bc4df31592b808dd87805796a31d82566 100644 (file)
--- a/media-sound/gnome-music/Manifest
+++ b/media-sound/gnome-music/Manifest
@@ -1 +1,2 @@
 DIST gnome-music-3.30.2.tar.xz 3027580 BLAKE2B 9cd5a10fecbf7fb962455bec7ee5392a305f3bab9ebb3e2f0d24066ffd6975377c57a722e850ee340e2990f61b06456f1fe963b80d57030416af7ea3b7f92b32 SHA512 b9fa33ccb76d747e22e1144b2c77dc88432386fdfd4f52720cb1ae3230c06fb899fec654dc1e126103e393eb0358a4385099743abe26505b9b7dcffe2d04a8c8
+DIST gnome-music-3.32.2.tar.xz 1391112 BLAKE2B ec64d48bcc137c69df77d9d9fadb3fa5c1809850e7a434d501cf6fd680500e57a4e6946ab591db9b715e728f0274f37b659afce53fd9213b3cf74f329f4373f3 SHA512 633748dcb5cf839f29059fd9bdd5283c455a4157d6c004168d9ef80352b83be3db547377034d0d78af0b6a84fec6fb941888bd53aa14c8bf51da880f04170a23

diff --git a/media-sound/gnome-music/gnome-music-3.32.2.ebuild b/media-sound/gnome-music/gnome-music-3.32.2.ebuild
new file mode 100644 (file)
index 0000000..49e7450
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-3.32.2.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="${PYTHON_DEPS}
+       net-libs/gnome-online-accounts[introspection]
+       >=dev-libs/gobject-introspection-1.54:=
+       >=x11-libs/gtk+-3.23.1:3[introspection]
+       >=dev-libs/libdazzle-3.28.0[introspection]
+       >=media-libs/libmediaart-1.9.1:2.0[introspection]
+       net-libs/libsoup:2.4[introspection]
+       >=app-misc/tracker-1.99.1:=[introspection(+)]
+       >=dev-python/pygobject-3.29.1:3[cairo,${PYTHON_USEDEP}]
+       >=dev-python/pycairo-1.14.0[${PYTHON_USEDEP}]
+       >=media-libs/grilo-0.3.4:0.3[introspection]
+       >=media-plugins/grilo-plugins-0.3.8:0.3
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${DEPEND}
+       || (
+               >=app-misc/tracker-miners-1.99.1[gstreamer]
+               >=app-misc/tracker-miners-1.99.1[ffmpeg]
+       )
+       x11-libs/libnotify[introspection]
+       media-libs/gstreamer:1.0[introspection]
+       media-libs/gst-plugins-base:1.0[introspection]
+       media-plugins/gst-plugins-meta:1.0
+       media-plugins/grilo-plugins:0.3[tracker]
+       x11-misc/xdg-user-dirs
+"
+BDEPEND="
+       dev-libs/libxml2:2
+       dev-util/itstool
+       >=sys-devel/gettext-0.19.8
+       virtual/pkgconfig
+"
+
+RESTRICT="test" # only does desktop and appdata validation, and latter needs network to validate screenshot from https
+
+pkg_setup() {
+       python_setup
+}
+
+src_prepare() {
+       sed -e '/sys.path.insert/d' -i "${S}"/gnome-music.in || die "python fixup sed failed"
+       xdg_src_prepare
+}
+
+src_install() {
+       meson_src_install
+       python_fix_shebang "${D}"/usr/bin/gnome-music
+       python_optimize
+}
+
+pkg_postinst() {
+       xdg_pkg_postinst
+       gnome2_schemas_update
+}
+
+pkg_postrm() {
+       xdg_pkg_postrm
+       gnome2_schemas_update
+}