sys-libs/libapparmor: version bump 2.13.4

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Michael Palimaka <kensington@gentoo.org>

diff --git a/sys-libs/libapparmor/Manifest b/sys-libs/libapparmor/Manifest
index 696ceaa4e8e9fa1e6babc10257f56c627d2f4a0d..ac257fe02491a823fd77e31962dd41ba4346d639 100644 (file)
--- a/sys-libs/libapparmor/Manifest
+++ b/sys-libs/libapparmor/Manifest
@@ -1 +1,2 @@
 DIST apparmor-2.13.3.tar.gz 7384974 BLAKE2B fd519f7b845db3203c8f47ff5abc7d9f20a7947fe86799b6fffcfaabaf5130fe0aa6589314f201c1df59cfd0fb22b80a12d364e9ca1279b14ba89ec469e3b346 SHA512 137b2bf026ec655b662e9c264d7d48d878db474a3f1cc5a38bfd7df2f85b682bddb77b091ab5595178231a0a262c9ae9cdd61409461cd889bdee156906ef1141
+DIST apparmor-2.13.4.tar.gz 7390179 BLAKE2B 49818a010d5e5757dd43710f2af925fbb62a9f8f9be74556ff31a9a8834bebac010762fc6bef3da8d295e487b65d0e0135f4be25bcb01a834846c5e5d65d92a4 SHA512 d42748bf36ae66849f79653a62d499e9d17a97c4d680fb653eb1c379d0593aaa09f7ddfc6f2fa0d2fb468bce05fb25444976f60a5ec24778fdd7ec20d1c13651

diff --git a/sys-libs/libapparmor/libapparmor-2.13.4.ebuild b/sys-libs/libapparmor/libapparmor-2.13.4.ebuild
new file mode 100644 (file)
index 0000000..0ccd352
--- /dev/null
+++ b/sys-libs/libapparmor/libapparmor-2.13.4.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python3_{5,6,7,8} )
+GENTOO_DEPEND_ON_PERL="no"
+
+inherit autotools distutils-r1 perl-functions
+
+MY_PV="$(ver_cut 1-2)"
+
+DESCRIPTION="Library to support AppArmor userspace utilities"
+HOMEPAGE="https://gitlab.com/apparmor/apparmor/wikis/home"
+SRC_URI="https://launchpad.net/apparmor/${MY_PV}/${PV}/+download/apparmor-${PV}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc +perl +python static-libs"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="perl? ( dev-lang/perl:= )
+       python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+       sys-devel/autoconf-archive
+       sys-devel/bison
+       sys-devel/flex
+       doc? ( dev-lang/perl )
+       perl? ( dev-lang/swig )
+       python? ( dev-lang/swig )"
+
+S=${WORKDIR}/apparmor-${PV}/libraries/${PN}
+
+PATCHES=( "${FILESDIR}/${PN}-2.10-symbol_visibility.patch" )
+
+# depends on the package already being installed
+RESTRICT="test"
+
+src_prepare() {
+       rm -r m4 || die "failed to remove bundled macros"
+       default
+       eautoreconf
+       use python && distutils-r1_src_prepare
+}
+
+src_configure() {
+       econf \
+               $(use_enable static-libs static) \
+               $(use_with perl) \
+               $(use_with python)
+}
+
+src_compile() {
+       emake -C src
+       emake -C include
+       use doc && emake -C doc
+       use perl && emake -C swig/perl
+
+       if use python ; then
+               pushd swig/python > /dev/null
+               emake libapparmor_wrap.c
+               distutils-r1_src_compile
+               popd > /dev/null
+       fi
+}
+
+src_install() {
+       emake DESTDIR="${D}" -C src install
+       emake DESTDIR="${D}" -C include install
+       use doc && emake DESTDIR="${D}" -C doc install
+
+       if use perl ; then
+               emake DESTDIR="${D}" -C swig/perl install
+               perl_set_version
+               insinto "${VENDOR_ARCH}"
+               doins swig/perl/LibAppArmor.pm
+
+               # bug 620886
+               perl_delete_localpod
+               perl_fix_packlist
+       fi
+
+       if use python ; then
+               pushd swig/python > /dev/null
+               distutils-r1_src_install
+
+               python_moduleinto LibAppArmor
+               python_foreach_impl python_domodule LibAppArmor.py
+               popd > /dev/null
+       fi
+
+       dodoc AUTHORS ChangeLog NEWS README
+
+       find "${D}" -name '*.la' -delete || die
+}