dev-qt/qtdeclarative: revision bump fixes crash when built with GCC 6

Closes: https://bugs.gentoo.org/626070
Package-Manager: Portage-2.3.8, Repoman-2.3.3

diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.7.1-r1.ebuild b/dev-qt/qtdeclarative/qtdeclarative-5.7.1-r1.ebuild
new file mode 100644 (file)
index 0000000..fae6450
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.7.1-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+inherit flag-o-matic python-any-r1 qt5-build
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+       KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="gles2 +jit localstorage +widgets xml"
+
+# qtgui[gles2=] is needed because of bug 504322
+COMMON_DEPEND="
+       ~dev-qt/qtcore-${PV}
+       ~dev-qt/qtgui-${PV}[gles2=]
+       ~dev-qt/qtnetwork-${PV}
+       ~dev-qt/qttest-${PV}
+       localstorage? ( ~dev-qt/qtsql-${PV} )
+       widgets? ( ~dev-qt/qtwidgets-${PV}[gles2=] )
+       xml? (
+               ~dev-qt/qtnetwork-${PV}
+               ~dev-qt/qtxmlpatterns-${PV}
+       )
+"
+DEPEND="${COMMON_DEPEND}
+       ${PYTHON_DEPS}
+"
+RDEPEND="${COMMON_DEPEND}
+       !<dev-qt/qtquickcontrols-5.7:5
+"
+
+src_prepare() {
+       # this is supposed to be handled by the build system (src/qml/qml.pro),
+       # fails because we override QMAKE_CXXFLAGS. bug 626070
+       if tc-is-gcc && [[ $(gcc-major-version) -ge 6 ]]; then
+               append-cxxflags -fno-delete-null-pointer-checks -fno-lifetime-dse
+       fi
+
+       use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
+
+       use localstorage || sed -i -e '/localstorage/d' \
+               src/imports/imports.pro || die
+
+       qt_use_disable_mod widgets widgets \
+               src/src.pro \
+               src/qmltest/qmltest.pro \
+               tests/auto/auto.pro \
+               tools/tools.pro \
+               tools/qmlscene/qmlscene.pro \
+               tools/qml/qml.pro
+
+       qt_use_disable_mod xml xmlpatterns \
+               src/imports/imports.pro \
+               tests/auto/quick/quick.pro \
+               tests/auto/quick/examples/examples.pro
+
+       qt5-build_src_prepare
+}