dev-perl/Apache-Reload: Enhance and enable tests

- EAPI6
- Fix description
- Fix missing build dependency
- Improve tests

Package-Manager: Portage-2.3.8, Repoman-2.3.3

diff --git a/dev-perl/Apache-Reload/Apache-Reload-0.130.0-r1.ebuild b/dev-perl/Apache-Reload/Apache-Reload-0.130.0-r1.ebuild
new file mode 100644 (file)
index 0000000..4d26ce8
--- /dev/null
+++ b/dev-perl/Apache-Reload/Apache-Reload-0.130.0-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DIST_AUTHOR=SHAY
+DIST_VERSION=0.13
+inherit perl-module
+
+DESCRIPTION="Automatically reload changed modules without restarting Apache"
+
+SLOT="0"
+LICENSE="Apache-2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="www-apache/mod_perl"
+DEPEND="${RDEPEND}
+       dev-perl/Apache-Test
+"
+
+src_test() {
+       local MODULES=(
+               "Apache::Reload ${DIST_VERSION}"
+               "Apache2::Reload ${DIST_VERSION}"
+       )
+       local failed=()
+       for dep in "${MODULES[@]}"; do
+               ebegin "Compile testing ${dep}"
+                       perl -Mblib="${S}" -M"${dep} ()" -e1
+               eend $? || failed+=( "$dep" )
+       done
+       if [[ ${failed[@]} ]]; then
+               echo
+               eerror "One or more modules failed compile:";
+               for dep in "${failed[@]}"; do
+                       eerror "  ${dep}"
+               done
+               die "Failing due to module compilation errors";
+       fi
+       perl-module_src_test
+}