media-libs/vulkan-loader: version bump to 1.2.133

Package-Manager: Portage-2.3.87, Repoman-2.3.20
Acked-by: Nick Sarnie <sarnex@gentoo.org>
Signed-off-by: Guilherme Amadio <amadio@gentoo.org>

diff --git a/media-libs/vulkan-loader/Manifest b/media-libs/vulkan-loader/Manifest
index 34fbe6b246648f8fb29e90782a1d85de93057ce5..c549cfefb60451025bf915f1b8c377989de3c868 100644 (file)
--- a/media-libs/vulkan-loader/Manifest
+++ b/media-libs/vulkan-loader/Manifest
@@ -1 +1,2 @@
 DIST vulkan-loader-1.1.125.tar.gz 1398802 BLAKE2B 7cf1f99f60b4b37bfad12580fc8809012a0540d928366b465a532fbf90e7d87bf42eeeff70b1a46efeadef9c599cad6009b122ed9c5c7298973207f05acc1032 SHA512 40e1e5c16491f0549eae3efc065c375c258b475d81e1c781a756c71ec329f390e2aba55ced5ed2005e938f9d074dffc1692e7e1e330a35f55460cae1606fdf2e
+DIST vulkan-loader-1.2.133.tar.gz 1401215 BLAKE2B 4a52e2735ed584f96f563dd23761c25169158a12488f50267375cb85dec411fed61f3ac0f090d77a650e9d055e384562d4fd644571b20e45ff0c316547b88647 SHA512 ba486cd0b20d1936a8a7e97509bdaa5e1c42f024428d6f710af80152d55f486c76db072ae44add089ff20eef21a768073904236e6d29d46dd1475d77d26f9907

diff --git a/media-libs/vulkan-loader/vulkan-loader-1.2.133.ebuild b/media-libs/vulkan-loader/vulkan-loader-1.2.133.ebuild
new file mode 100644 (file)
index 0000000..8d64aee
--- /dev/null
+++ b/media-libs/vulkan-loader/vulkan-loader-1.2.133.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+if [[ "${PV}" == "9999" ]]; then
+       EGIT_REPO_URI="https://github.com/KhronosGroup/Vulkan-Loader.git"
+       EGIT_SUBMODULES=()
+       inherit git-r3
+else
+       if [[ -z ${SNAPSHOT_COMMIT} ]]; then
+               MY_PV=v${PV}
+               MY_P=Vulkan-Loader-${PV}
+       else
+               MY_PV=${SNAPSHOT_COMMIT}
+               MY_P=Vulkan-Loader-${SNAPSHOT_COMMIT}
+       fi
+       KEYWORDS="~amd64 ~ppc64 ~x86"
+       SRC_URI="https://github.com/KhronosGroup/Vulkan-Loader/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+       S="${WORKDIR}"/${MY_P}
+fi
+
+inherit toolchain-funcs python-any-r1 cmake-multilib
+
+DESCRIPTION="Vulkan Installable Client Driver (ICD) Loader"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Loader"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="layers wayland X"
+
+PDEPEND="layers? ( media-libs/vulkan-layers:=[${MULTILIB_USEDEP}] )"
+DEPEND="${PYTHON_DEPS}
+       >=dev-util/vulkan-headers-${PV}
+       wayland? ( dev-libs/wayland:=[${MULTILIB_USEDEP}] )
+       X? (
+               x11-libs/libX11:=[${MULTILIB_USEDEP}]
+               x11-libs/libXrandr:=[${MULTILIB_USEDEP}]
+       )"
+
+multilib_src_configure() {
+       # Integrated clang assembler doesn't work with x86 - Bug #698164
+       if tc-is-clang && [[ ${ABI} == x86 ]]; then
+               append-cflags -fno-integrated-as
+       fi
+
+       local mycmakeargs=(
+               -DCMAKE_SKIP_RPATH=True
+               -DBUILD_TESTS=False
+               -DBUILD_LOADER=True
+               -DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+               -DBUILD_WSI_XCB_SUPPORT=$(usex X)
+               -DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+               -DVULKAN_HEADERS_INSTALL_DIR="/usr"
+       )
+       cmake-utils_src_configure
+}
+
+multilib_src_install() {
+       keepdir /etc/vulkan/icd.d
+
+       cmake-utils_src_install
+}
+
+pkg_postinst() {
+       einfo "USE=demos has been dropped as per upstream packaging"
+       einfo "vulkaninfo is now available in the dev-util/vulkan-tools package"
+}