dev-python/{doublex-expects,expects,mamba}: EAPI 7 + py37

All in one commit because of this depenceny graph:
- doublex-expects: RDEPEND expects, DEPEND mamba
- expects: DEPEND mamba
- mamba: DEPEND expects, doublex-expects
Bug: https://bugs.gentoo.org/711092
Signed-off-by: Sebastian Pipping <sping@gentoo.org>

diff --git a/dev-python/doublex-expects/doublex-expects-0.7.0_rc2-r1.ebuild b/dev-python/doublex-expects/doublex-expects-0.7.0_rc2-r1.ebuild
new file mode 100644 (file)
index 0000000..cd9fa0d
--- /dev/null
+++ b/dev-python/doublex-expects/doublex-expects-0.7.0_rc2-r1.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1 vcs-snapshot
+
+MY_PV=${PV/_/}
+
+DESCRIPTION="Expects matchers for Doublex test doubles assertions"
+HOMEPAGE="https://github.com/jaimegildesagredo/doublex-expects"
+SRC_URI="https://github.com/jaimegildesagredo/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+       test? ( dev-python/mamba[${PYTHON_USEDEP}] )
+"
+RDEPEND="
+       dev-python/doublex[${PYTHON_USEDEP}]
+       >=dev-python/expects-0.8.0_rc1[${PYTHON_USEDEP}]
+"
+
+python_test() {
+       mamba || die "Tests failed under ${EPYTHON}"
+}

diff --git a/dev-python/expects/expects-0.8.0-r1.ebuild b/dev-python/expects/expects-0.8.0-r1.ebuild
new file mode 100644 (file)
index 0000000..92b6a96
--- /dev/null
+++ b/dev-python/expects/expects-0.8.0-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Expressive and extensible TDD/BDD assertion library for Python"
+HOMEPAGE="https://github.com/jaimegildesagredo/expects"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+       doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+       test? ( dev-python/mamba[${PYTHON_USEDEP}] )
+"
+RDEPEND=""
+
+python_compile_all() {
+       use doc && emake -C docs html
+}
+
+python_test() {
+       mamba || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+       use doc && local HTML_DOCS=( docs/_build/html/. )
+
+       distutils-r1_python_install_all
+}

diff --git a/dev-python/mamba/mamba-0.8.6-r1.ebuild b/dev-python/mamba/mamba-0.8.6-r1.ebuild
new file mode 100644 (file)
index 0000000..fae6d37
--- /dev/null
+++ b/dev-python/mamba/mamba-0.8.6-r1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="... testing tool ... Born under the banner of Behavior Driven Development"
+HOMEPAGE="http://nestorsalceda.github.io/mamba"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+       test? (
+               >=dev-python/doublex-expects-0.7.0_rc1[${PYTHON_USEDEP}]
+               >=dev-python/expects-0.8.0_rc2[${PYTHON_USEDEP}]
+               >=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+       )
+"
+RDEPEND="
+       >=dev-python/clint-0.3.1[${PYTHON_USEDEP}]
+       >=dev-python/coverage-3.7.1[${PYTHON_USEDEP}]
+       >=dev-python/watchdog-0.8.1[${PYTHON_USEDEP}]
+"
+
+python_test() {
+       "${PYTHON}" -m mamba.cli || die "Tests failed under ${EPYTHON}"
+}