x11-misc/gpaste: initial import of version 3.14

Gentoo-Bug: 374101

diff --git a/x11-misc/gpaste/Manifest b/x11-misc/gpaste/Manifest
new file mode 100644 (file)
index 0000000..372affd
--- /dev/null
+++ b/x11-misc/gpaste/Manifest
@@ -0,0 +1 @@
+DIST gpaste-3.14.tar.gz 146295 SHA256 55d6547aec756fc55f88adbebd6685147e23cac5683308d2e424c2982ce2dbbd SHA512 ffafa6ef19a65af5cea2a74a6c7ea6e33a6097d4aeae6c78628cfadf2e2fde1ae30eb2bb5723b4f58c225ac68a2db5f3f114ffa9da7544b7765bc5fe033d824f WHIRLPOOL 4c178c1dc5e4f905bdf406c4ac23b8e74bfba60d9f0c1a93978153deedc1a8eaba989fcb453ace1a16aecdf4effd0d8bc12a03ac28b3c09a427a10151eb032ab

diff --git a/x11-misc/gpaste/gpaste-3.14.ebuild b/x11-misc/gpaste/gpaste-3.14.ebuild
new file mode 100644 (file)
index 0000000..f259be1
--- /dev/null
+++ b/x11-misc/gpaste/gpaste-3.14.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils autotools gnome2-utils vala vcs-snapshot
+
+DESCRIPTION="Clipboard management system"
+HOMEPAGE="https://github.com/Keruspe/GPaste"
+SRC_URI="https://github.com/Keruspe/GPaste/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+applet gnome vala"
+
+CDEPEND="
+       dev-util/appdata-tools
+       >=dev-libs/glib-2.40:2
+       >=dev-libs/gobject-introspection-1.42.0
+       sys-apps/dbus
+       >=x11-libs/gdk-pixbuf-2.26:2
+       >=x11-libs/gtk+-3.12:3
+       x11-libs/libX11
+       x11-libs/libXi
+       gnome? (
+               gnome-base/gnome-control-center:2
+               media-libs/clutter
+               x11-libs/pango
+       )
+"
+RDEPEND="${CDEPEND}
+       gnome? (
+               gnome-base/gnome-shell
+       )
+"
+DEPEND="${CDEPEND}
+       dev-util/intltool
+       virtual/pkgconfig
+       vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+       eautoreconf
+       intltoolize --force --automake || die "intltoolize error"
+       vala_src_prepare
+
+       if ! use gnome ; then
+               echo "" > data/control-center.mk || die
+       fi
+}
+
+src_configure() {
+       econf \
+               $(use_enable vala) \
+               $(use_enable applet) \
+               --disable-unity \
+               $(use_enable gnome gnome-shell-extension) \
+               --disable-static \
+               --disable-schemas-compile
+}
+
+src_install() {
+       default
+       prune_libtool_files
+}
+
+pkg_preinst() {
+       gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+       gnome2_schemas_update
+}
+
+pkg_postrm() {
+       gnome2_schemas_update
+}

diff --git a/x11-misc/gpaste/metadata.xml b/x11-misc/gpaste/metadata.xml
new file mode 100644 (file)
index 0000000..4601862
--- /dev/null
+++ b/x11-misc/gpaste/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+       <maintainer>
+               <email>hasufell@gentoo.org</email>
+               <name>Julian Ospald</name>
+       </maintainer>
+       <use>
+               <flag name='applet'>Enable gpaste-applet</flag>
+               <flag name='gnome'>Enable proper gnome support and
+                       enable gnome shell extension.</flag>
+               <flag name='vala'>Build vala bindings</flag>
+       </use>
+</pkgmetadata>