media-gfx/geeqie: 1.5.1 bump

Bugfix release on recent 1.5

Package-Manager: Portage-2.3.72, Repoman-2.3.17
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

diff --git a/media-gfx/geeqie/Manifest b/media-gfx/geeqie/Manifest
index 9d22d0eaa1ce908093fa69de593c11b51d5a010d..95c4f2f3591dddec5e480d273d5244b0ec37d39b 100644 (file)
--- a/media-gfx/geeqie/Manifest
+++ b/media-gfx/geeqie/Manifest
@@ -1,2 +1,3 @@
 DIST geeqie-1.4.tar.xz 35881152 BLAKE2B 2932ac379abaee2b742b66daff544f29d7bf0aac82ff97f92e10ac7902ad874badcbb143f562c665d94f6297331090d0746373979a745f338a738078b72538a4 SHA512 a88b6dcf30847e38c109f5bc6436d93f6b4e1336a094c6b8a45db117830117120bf58f390afcd8a4b7aaf2934f995c3f75ac33a7faf56bfc2bcc9bd4eebfb205
+DIST geeqie-1.5.1.tar.xz 1587116 BLAKE2B f8742a88eefd90fb1e7e1d1365058cef190b6231fcb001faa9f110676e8403c8e5959f9af398d6fa1ddc4e4c62439728904c6c39f5095f476014a5b7b74b4d16 SHA512 265eade90afe45856855e856c5f640786ca2e3add57c3ade8ca380d075297f96bf44c6e0c4fd6eabbc2666a37f898b50d37dd2e01d77875b8a622d72d8a0e6ac
 DIST geeqie-1.5.tar.xz 1585780 BLAKE2B 6dc0a30c26f25988cbd3fa81a916642504e9f6f280b03d78c820cbf5b453d8a392d3c8da8d482de24b3c39e7e9ba0663879d651c60a8061b8034d2c526007944 SHA512 2b87d543d8d77a4fec331fd1b73ca2038912362fc1f94c9b0f163dcc7c2dd58118e175c5540aecafb0581708ea5c2a5a321dde09f644e2322bd4ca5c0284b722

diff --git a/media-gfx/geeqie/geeqie-1.5.1.ebuild b/media-gfx/geeqie/geeqie-1.5.1.ebuild
new file mode 100644 (file)
index 0000000..5323596
--- /dev/null
+++ b/media-gfx/geeqie/geeqie-1.5.1.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools xdg-utils
+
+DESCRIPTION="A lightweight GTK image viewer forked from GQview"
+HOMEPAGE="http://www.geeqie.org"
+SRC_URI="http://www.geeqie.org/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug doc exif ffmpegthumbnailer gpu-accel gtk3 jpeg lcms lirc lua map nls pdf tiff xmp"
+
+RDEPEND="
+       virtual/libintl
+       doc? ( app-text/gnome-doc-utils )
+       ffmpegthumbnailer? ( media-video/ffmpegthumbnailer )
+       gpu-accel? ( media-libs/clutter-gtk )
+       gtk3? ( x11-libs/gtk+:3 )
+       !gtk3? ( x11-libs/gtk+:2 )
+       jpeg? ( virtual/jpeg:0 )
+       lcms? ( media-libs/lcms:2 )
+       lirc? ( app-misc/lirc )
+       lua? ( >=dev-lang/lua-5.1:= )
+       map? ( media-libs/libchamplain:0.12 )
+       pdf? ( >=app-text/poppler-0.62[cairo] )
+       tiff? ( media-libs/tiff:0 )
+       xmp? ( >=media-gfx/exiv2-0.17:=[xmp] )
+       !xmp? ( exif? ( >=media-gfx/exiv2-0.17:= ) )"
+DEPEND="${RDEPEND}
+       dev-util/glib-utils"
+BDEPEND="
+       dev-util/intltool
+       virtual/pkgconfig
+       nls? ( sys-devel/gettext )"
+
+REQUIRED_USE="gpu-accel? ( gtk3 )
+       map? ( gpu-accel )"
+
+src_prepare() {
+       default
+
+       # Remove -Werror (gcc changes may add new warnings)
+       sed -e '/CFLAGS/s/-Werror //g' -i configure.ac || die
+
+       eautoreconf
+}
+
+src_configure() {
+       local myconf="--disable-dependency-tracking
+               --with-readmedir="${EPREFIX}"/usr/share/doc/${PF}
+               $(use_enable debug debug-log)
+               $(use_enable ffmpegthumbnailer)
+               $(use_enable gpu-accel)
+               $(use_enable gtk3)
+               $(use_enable jpeg)
+               $(use_enable lcms)
+               $(use_enable lua)
+               $(use_enable lirc)
+               $(use_enable map)
+               $(use_enable nls)
+               $(use_enable pdf)
+               $(use_enable tiff)"
+
+       if use exif || use xmp; then
+               myconf="${myconf} --enable-exiv2"
+       else
+               myconf="${myconf} --disable-exiv2"
+       fi
+
+       econf ${myconf}
+}
+
+src_install() {
+       emake DESTDIR="${D}" install
+
+       rm -f "${D}/usr/share/doc/${PF}/COPYING"
+       # Application needs access to the uncompressed file
+       docompress -x /usr/share/doc/${PF}/README.md
+}
+
+pkg_postinst() {
+       xdg_desktop_database_update
+
+       elog "Some plugins may require additional packages"
+       elog "- Image rotate plugin: media-gfx/fbida (JPEG), media-gfx/imagemagick (TIFF/PNG)"
+       elog "- RAW images plugin: media-gfx/ufraw"
+}
+
+pkg_postrm() {
+       xdg_desktop_database_update
+}