x11-libs/pango: add patchset (including fix of Java app crashes)

Closes: https://bugs.gentoo.org/671136
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

diff --git a/x11-libs/pango/Manifest b/x11-libs/pango/Manifest
index 16e3d0bd4c2f1cd7a94f6e1ab832c06057722c98..478d90da156aeb94f5472c4521ae14913279650c 100644 (file)
--- a/x11-libs/pango/Manifest
+++ b/x11-libs/pango/Manifest
@@ -1,2 +1,3 @@
 DIST pango-1.40.14.tar.xz 858388 BLAKE2B 1afcff08c38aa59ec57cdf43aa503e70a8c03b7d59c730060c9e3537f78ffe9a63e3aa1cb74ce9ce8d72541b5a5be8becb951f665f4663b108114686c41452c8 SHA512 35ba7bc8be3992f206ccc2cc5aca0b94e2a3832f887fc9c45b0e29fddcb9051ce05a74377de0ca4ff95a87983b15688fa5d379d592faf87aa8eaca25ac18b7ea
+DIST pango-1.42.4-patchset.tar.xz 6040 BLAKE2B ec3f1a6a4de30e0864e7f0bf0950cb7a7b4bada8c3db496a8e5b1e770f221ae72b43167178445ea9cd0d6b88e51d2af49e7fdf27b2e792997fe7c37e55d429c1 SHA512 b7654c3493931e3c6d3cbd40ee49c5cbebaf403954bae75dea80e9f03e12dd5082548aff6a9e778821b8f935e227a7efaad4c1b980fa108e7258042221cadfc1
 DIST pango-1.42.4.tar.xz 833876 BLAKE2B 7de1094a29750b9e59ea1e5c92644fa5d6b835828d027963a53cce3f204ee1ea0042ec492e209de9136f05ca131ccda959bc477d4f6e9c72e5f620ddf4235f26 SHA512 993e97f647eba0c5ed90bcfcb8228bf67fa3f20b1f4331e4e40a30788d7c3ac55eee1209471bf21df125cb8fc6121acc8062a9da2f8a7d6cbe8e9ad13a9320dc

diff --git a/x11-libs/pango/pango-1.42.4-r1.ebuild b/x11-libs/pango/pango-1.42.4-r1.ebuild
new file mode 100644 (file)
index 0000000..676a13a
--- /dev/null
+++ b/x11-libs/pango/pango-1.42.4-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 multilib-minimal toolchain-funcs
+
+DESCRIPTION="Internationalized text layout and rendering library"
+HOMEPAGE="http://www.pango.org/"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="LGPL-2+ FTL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+IUSE="X +introspection test"
+
+RDEPEND="
+       >=media-libs/harfbuzz-1.4.2:=[glib(+),truetype(+),${MULTILIB_USEDEP}]
+       >=dev-libs/glib-2.50.2:2[${MULTILIB_USEDEP}]
+       >=media-libs/fontconfig-2.12.92:1.0=[${MULTILIB_USEDEP}]
+       >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}]
+       >=x11-libs/cairo-1.12.14-r4:=[X?,${MULTILIB_USEDEP}]
+       >=dev-libs/fribidi-0.19.7[${MULTILIB_USEDEP}]
+       introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
+       X? (
+               >=x11-libs/libXrender-0.9.8[${MULTILIB_USEDEP}]
+               >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+               >=x11-libs/libXft-2.3.1-r1[${MULTILIB_USEDEP}]
+       )
+"
+DEPEND="${RDEPEND}
+       dev-util/glib-utils
+       >=dev-util/gtk-doc-am-1.20
+       virtual/pkgconfig[${MULTILIB_USEDEP}]
+       test? ( media-fonts/cantarell )
+       X? ( x11-base/xorg-proto )
+       !<=sys-devel/autoconf-2.63:2.5
+"
+
+PATCHES=(
+       "${WORKDIR}"/patches/ # bug fix cherry-picks from master by 20190216; each patch has commit id of origin/master included and will be part of 1.43.1/1.44
+)
+
+src_prepare() {
+       gnome2_src_prepare
+       # This should be updated if next release fails to pre-generate the manpage as well, or src_prepare removed if is properly generated
+       # https://gitlab.gnome.org/GNOME/pango/issues/270
+       cp -v "${FILESDIR}"/${PV}-pango-view.1.in "${S}/utils/pango-view.1.in" || die
+}
+
+multilib_src_configure() {
+       tc-export CXX
+
+       ECONF_SOURCE=${S} \
+       gnome2_src_configure \
+               --with-cairo \
+               $(multilib_native_use_enable introspection) \
+               $(use_with X xft) \
+               "$(usex X --x-includes="${EPREFIX}/usr/include" "")" \
+               "$(usex X --x-libraries="${EPREFIX}/usr/$(get_libdir)" "")"
+
+       if multilib_is_native_abi; then
+               ln -s "${S}"/docs/html docs/html || die
+       fi
+}
+
+multilib_src_install() {
+       gnome2_src_install
+}