x11-libs/libva: Bump to version 2.7.0

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

diff --git a/x11-libs/libva/Manifest b/x11-libs/libva/Manifest
index 001d8c87af1712c49d2e7427194de818d56898a9..de5f703ff482616fa1fe48583612461657773087 100644 (file)
--- a/x11-libs/libva/Manifest
+++ b/x11-libs/libva/Manifest
@@ -1,2 +1,3 @@
 DIST libva-2.5.0.tar.bz2 459677 BLAKE2B d6e5bf94bcbda0a724634164bd8cf91efbdbe36120e62e7e7eefcd749afffec1950d8904318b472c81ae07490c559c68b0853725c654a08592457118cd5d6a83 SHA512 ffaeb9cf8ed1f93073c1cb3e58f5b3d3612e81622d02f8e428c089f625d4370b496b7681ac2fc2823c48670c9fd3da50893b1db51de768cf0f5d866e2ee78106
 DIST libva-2.6.1.tar.bz2 466497 BLAKE2B d4ea6e6d0102722206d94725932f0b3cf650bab3f02235f4c627dc83e5417b786f9524430d793f1067d002a0c9d7cbc92a7c740383c698d225a14946e1bb90ba SHA512 b57f0c0dda5ebadc92f56bc7fb835c2931cafffca9413fb4d244ea1dd47b603376323e6bebf144ccb2d2cf3499c64b101f8e03ff1809bd81242718d224d2d17d
+DIST libva-2.7.0.tar.bz2 477326 BLAKE2B 4ec99cebe3be8de46a7663b36cf5cededc271dc3ce6f6a42a2e861043c3bc3a1cb93ea31c4a2b7a1e5d7789de128066728b7d910bf19eceab107fe3b12966126 SHA512 4922d7c0d706d160b6885a045ca585e822275f04e66142d963b0e8e3efcf2ada81edc1255d0eb334c46c51b994e35c080d8ced10bf29a153cabe5c6991de3a68

diff --git a/x11-libs/libva/libva-2.7.0.ebuild b/x11-libs/libva/libva-2.7.0.ebuild
new file mode 100644 (file)
index 0000000..016d79e
--- /dev/null
+++ b/x11-libs/libva/libva-2.7.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit multilib-minimal
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="https://01.org/linuxmedia/vaapi"
+
+if [[ ${PV} = *9999* ]] ; then # Live ebuild
+       inherit autotools git-r3
+       EGIT_BRANCH=master
+       EGIT_REPO_URI="https://github.com/intel/libva"
+       AUTOTOOLS_AUTORECONF="yes"
+else
+       SRC_URI="https://github.com/intel/libva/releases/download/${PV}/${P}.tar.bz2"
+       KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="MIT"
+SLOT="0/$(ver_cut 1)"
+IUSE="+drm opengl utils vdpau wayland X"
+
+VIDEO_CARDS="nvidia intel i965 nouveau"
+for x in ${VIDEO_CARDS}; do
+       IUSE+=" video_cards_${x}"
+done
+
+RDEPEND="
+       >=x11-libs/libdrm-2.4.46[${MULTILIB_USEDEP}]
+       opengl? ( >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}] )
+       wayland? ( >=dev-libs/wayland-1.11[${MULTILIB_USEDEP}] )
+       X? (
+               >=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+               >=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+               >=x11-libs/libXfixes-5.0.1[${MULTILIB_USEDEP}]
+       )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+       virtual/pkgconfig
+"
+PDEPEND="video_cards_nvidia? ( >=x11-libs/libva-vdpau-driver-0.7.4-r1[${MULTILIB_USEDEP}] )
+       video_cards_nouveau? ( >=x11-libs/libva-vdpau-driver-0.7.4-r3[${MULTILIB_USEDEP}] )
+       vdpau? ( >=x11-libs/libva-vdpau-driver-0.7.4-r1[${MULTILIB_USEDEP}] )
+       video_cards_intel? ( >=x11-libs/libva-intel-driver-2.0.0[${MULTILIB_USEDEP}] )
+       video_cards_i965? ( >=x11-libs/libva-intel-driver-2.0.0[${MULTILIB_USEDEP}] )
+       utils? ( media-video/libva-utils )
+"
+
+REQUIRED_USE="|| ( drm wayland X )
+       opengl? ( X )"
+
+DOCS=( NEWS )
+
+MULTILIB_WRAPPED_HEADERS=(
+/usr/include/va/va_backend_glx.h
+/usr/include/va/va_x11.h
+/usr/include/va/va_dri2.h
+/usr/include/va/va_dricommon.h
+/usr/include/va/va_glx.h
+)
+
+src_prepare() {
+       default
+       [[ "${PV}" == *9999* ]] && eautoreconf
+}
+
+multilib_src_configure() {
+       local myeconfargs=(
+               --with-drivers-path="${EPREFIX}/usr/$(get_libdir)/va/drivers"
+               $(use_enable opengl glx)
+               $(use_enable X x11)
+               $(use_enable wayland)
+               $(use_enable drm)
+       )
+       ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+       find "${ED}" -type f -name "*.la" -delete || die
+}