dev-libs/libinput: Version bump to 1.15.5

Signed-off-by: Matt Turner <mattst88@gentoo.org>

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 7a2a45eea4fcc092b47a8012bb3c781645b342ba..a7fdc9fb1213b51b328133bcc702bd955e1b3752 100644 (file)
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1 +1,2 @@
 DIST libinput-1.15.4.tar.xz 580616 BLAKE2B cac324f08b8dc3c6cc18ca62d528c3a00fbd70a1d434aa171da2e144d8d74f961bcb491f6dc39b365f766ea8e5ed87b29b1dd5aa9f62b12707f8e49e5c63a5d7 SHA512 4659818952dc729cd5bdb78ebe21edbbacbf8a66a592b13ba30f3bb4c4e264208ec94440a253cfa4edc8b2ef904954eecea6be0f8d63cf239e3858d3abb64a80
+DIST libinput-1.15.5.tar.xz 582800 BLAKE2B 8575dbe6699230610e05f4c7e9e72aebb1fb765be1d305ba6d9fcf69c6efc990ec78bd0746b29921a2414df99c536c3f267b1dd1d6d98c872e360fc16572e2a4 SHA512 a0a3a325048841fc017e19d3bc5f5490605972ab9e2730dc5678bda7efb7a5b1fa6f531f3c8abd8393899ec383d8d2bcfd586eacee04fc1fbda0e02ba2af956a

diff --git a/dev-libs/libinput/libinput-1.15.5.ebuild b/dev-libs/libinput/libinput-1.15.5.ebuild
new file mode 100644 (file)
index 0000000..7ae9b0b
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.15.5.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2014-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+       virtual/pkgconfig
+       doc? (
+               $(python_gen_any_dep '
+                       dev-python/commonmark[${PYTHON_USEDEP}]
+                       dev-python/recommonmark[${PYTHON_USEDEP}]
+                       dev-python/sphinx[${PYTHON_USEDEP}]
+                       >=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+               ')
+               >=app-doc/doxygen-1.8.3
+               >=media-gfx/graphviz-2.38.0
+       )
+"
+#      test? ( dev-util/valgrind )
+RDEPEND="
+       input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+       >=dev-libs/libevdev-1.3
+       >=sys-libs/mtdev-1.1
+       virtual/libudev:=
+       virtual/udev
+"
+DEPEND="${RDEPEND}
+       test? ( >=dev-libs/check-0.9.10 )"
+
+python_check_deps() {
+       has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+       has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+       has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+       has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+       use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+       # gui can be built but will not be installed
+       local emesonargs=(
+               -Ddebug-gui=false
+               $(meson_use doc documentation)
+               $(meson_use input_devices_wacom libwacom)
+               $(meson_use test tests)
+               -Dudev-dir="${EPREFIX}$(get_udevdir)"
+       )
+       meson_src_configure
+}
+
+src_install() {
+       meson_src_install
+       if use doc ; then
+               docinto html
+               dodoc -r "${BUILD_DIR}"/Documentation/.
+       fi
+}
+
+pkg_postinst() {
+       pkgname="dev-python/python-libevdev"
+       if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "${pkgname}"; then
+               einfo "${pkgname} must be installed to use the"
+               einfo "libinput measure and libinput replay tools."
+       fi
+
+       udevadm hwdb --update --root="${ROOT}"
+}