media-libs/gst-rtsp-server: bump to 1.12.2

Package-Manager: Portage-2.3.6, Repoman-2.3.2

diff --git a/media-libs/gst-rtsp-server/Manifest b/media-libs/gst-rtsp-server/Manifest
index 9e880a5ef095028f0d7725ac9ccf8e1d426c6ab4..1f07a64fca8ab34461ad3d0e09a1a65fb7e884ca 100644 (file)
--- a/media-libs/gst-rtsp-server/Manifest
+++ b/media-libs/gst-rtsp-server/Manifest
@@ -1,2 +1,3 @@
 DIST gst-rtsp-0.10.8.tar.bz2 567670 SHA256 9915887cf8515bda87462c69738646afb715b597613edc7340477ccab63a6617 SHA512 c5020cffa9334b7d9c6b9dbe6f32bd4580eeee1c67689269d232e954ef9d96d8b988e3fb19da89701eae26419df0bf6de5796f7780cfbedda4c07154b1c1ebd7 WHIRLPOOL 6bd260edaef5ab003ef7176d84c46d5a94d365af51226108af9ab845d6e5910d90c721d5fd87e7fe93b141a82e5114b4c674a1d2500ef57302bf845c87f5463c
 DIST gst-rtsp-server-1.10.3.tar.xz 628808 SHA256 baf9f7d229711cb3d823a447a930132f809b3321eab3535491bb01c8a21566fe SHA512 08bd56a04dbfda9d9509385e0ae255f596a4da36d0f998c3c7cb319f7050d3fb8718d11bb3304c667351a859e332f39b8013579cbc70cdb978cb358ae6063f7c WHIRLPOOL e323888dedb1f15360c27015d0176edfb58d70d11d859fa3768f73cefe4d1d6f694652af64268296eab5480588c7e864f8739d86d615009c38ac29bfd8c58d52
+DIST gst-rtsp-server-1.12.2.tar.xz 630356 SHA256 d8ba9264e8ae6e440293328e759e40456f161aa66077b3143dd07581136190b3 SHA512 6971fcdf12512a106dfe158ad5032792f4347fb3f577305a9762606ebc41a9c2fb6ba8325f79e320738ecf0097275829ab76ebfe68e13d29fd81134d18663e67 WHIRLPOOL 5933137d4e2288df491ca966036226651f3f79ada27f61c2388b5dc7cb58baa604f20935399e795b2c5ea686eba3aa2110445037b2614809dd93c79fbe2f5ef1

diff --git a/media-libs/gst-rtsp-server/gst-rtsp-server-1.12.2.ebuild b/media-libs/gst-rtsp-server/gst-rtsp-server-1.12.2.ebuild
new file mode 100644 (file)
index 0000000..e17cb55
--- /dev/null
+++ b/media-libs/gst-rtsp-server/gst-rtsp-server-1.12.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils gstreamer
+
+DESCRIPTION="A GStreamer based RTSP server"
+HOMEPAGE="https://people.freedesktop.org/~wtay/"
+
+LICENSE="LGPL-2"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples +introspection static-libs test"
+
+# FIXME: check should depend on USE=test but check is losy
+# configure says good and bad are required by macros forces them to be optional
+# they are only used in unittests anyway.
+RDEPEND="
+       >=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+       >=media-libs/gstreamer-${PV}:${SLOT}[introspection?,${MULTILIB_USEDEP}]
+       >=media-libs/gst-plugins-base-${PV}:${SLOT}[introspection?,${MULTILIB_USEDEP}]
+       introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+"
+DEPEND="${RDEPEND}
+       >=dev-libs/check-0.9.2
+       >=dev-util/gtk-doc-am-1.12
+       test? (
+               >=media-libs/gst-plugins-bad-${PV}:${SLOT}[introspection?,${MULTILIB_USEDEP}]
+               >=media-libs/gst-plugins-good-${PV}:${SLOT}[${MULTILIB_USEDEP}]
+       )
+"
+
+# Due to gstreamer src_configure
+QA_CONFIGURE_OPTIONS="--enable-nls"
+
+multilib_src_configure() {
+       # debug: only adds -g to CFLAGS
+       # docbook: nothing behind that switch
+       # libcgroup is automagic and only used in examples
+       gstreamer_multilib_src_configure \
+               --disable-examples \
+               --disable-docbook \
+               --disable-gtk-doc \
+               $(multilib_native_use_enable introspection) \
+               $(use_enable static-libs static) \
+               $(use_enable test tests) \
+               LIBCGROUP_LIBS= \
+               LIBCGROUP_FLAGS=
+
+       # work-around gtk-doc out-of-source brokedness
+       if multilib_is_native_abi ; then
+               ln -s "${S}"/docs/libs/${d}/html docs/libs/${d}/html || die
+       fi
+}
+
+multilib_src_install() {
+       emake install DESTDIR="${D}"
+       # Handle broken upstream modifications to defaults of gtk-doc
+       emake install -C docs/libs DESTDIR="${D}"
+       prune_libtool_files
+}
+
+multilib_src_install_all() {
+       einstalldocs
+
+       if use examples ; then
+               insinto /usr/share/doc/${PF}/examples
+               doins "${S}"/examples/*.c
+       fi
+}