media-libs/libplacebo: Lift dev-util/glslang version restriction

Closes: https://bugs.gentoo.org/698124
Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

diff --git a/media-libs/libplacebo/libplacebo-1.21.0-r1.ebuild b/media-libs/libplacebo/libplacebo-1.21.0-r1.ebuild
new file mode 100644 (file)
index 0000000..39c90c7
--- /dev/null
+++ b/media-libs/libplacebo/libplacebo-1.21.0-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ "${PV}" == "9999" ]]; then
+       EGIT_REPO_URI="https://code.videolan.org/videolan/libplacebo.git"
+       inherit git-r3
+else
+       KEYWORDS="~amd64 ~x86"
+       SRC_URI="https://code.videolan.org/videolan/libplacebo/-/archive/v${PV}/libplacebo-v${PV}.tar.gz"
+       S="${WORKDIR}/${PN}-v${PV}"
+fi
+
+inherit meson multilib-minimal
+
+DESCRIPTION="Reusable library for GPU-accelerated image processing primitives"
+HOMEPAGE="https://github.com/haasn/libplacebo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="glslang lcms +shaderc test +vulkan"
+REQUIRED_USE="vulkan? ( || ( glslang shaderc ) )"
+
+RDEPEND="glslang? ( dev-util/glslang[${MULTILIB_USEDEP}] )
+       lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )
+       shaderc? ( >=media-libs/shaderc-2017.2[${MULTILIB_USEDEP}] )
+       vulkan? ( media-libs/vulkan-loader[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+multilib_src_configure() {
+       local emesonargs=(
+               $(meson_feature glslang)
+               $(meson_feature lcms)
+               $(meson_feature shaderc)
+               $(meson_feature vulkan)
+               $(meson_use test tests)
+       )
+       meson_src_configure
+}
+
+multilib_src_compile() {
+       meson_src_compile
+}
+
+multilib_src_test() {
+       meson_src_test
+}
+
+multilib_src_install() {
+       meson_src_install
+}

diff --git a/media-libs/libplacebo/libplacebo-9999.ebuild b/media-libs/libplacebo/libplacebo-9999.ebuild
index eda8818f5919bcc99db803930d77c4c625d59339..9162ffc382594e71a91505eb53f779a00d3388d8 100644 (file)
--- a/media-libs/libplacebo/libplacebo-9999.ebuild
+++ b/media-libs/libplacebo/libplacebo-9999.ebuild
@@ -22,7 +22,7 @@ SLOT="0"
 IUSE="glslang lcms +shaderc test +vulkan"
 REQUIRED_USE="vulkan? ( || ( glslang shaderc ) )"
 
-RDEPEND="glslang? ( <dev-util/glslang-7.10[${MULTILIB_USEDEP}] )
+RDEPEND="glslang? ( dev-util/glslang[${MULTILIB_USEDEP}] )
        lcms? ( media-libs/lcms:2[${MULTILIB_USEDEP}] )
        shaderc? ( >=media-libs/shaderc-2017.2[${MULTILIB_USEDEP}] )
        vulkan? ( media-libs/vulkan-loader[${MULTILIB_USEDEP}] )"