xfce-extra/xfce4-screensaver: Bump to 0.1.5

Bump to 0.1.5 release.  Includes elogind support.

Closes: https://bugs.gentoo.org/681344
Signed-off-by: Michał Górny <mgorny@gentoo.org>

diff --git a/xfce-extra/xfce4-screensaver/Manifest b/xfce-extra/xfce4-screensaver/Manifest
index 2bbb97f6345946bd892483bda5f4174db056d730..9c390a005b98134d5486d4189d245516c277a33b 100644 (file)
--- a/xfce-extra/xfce4-screensaver/Manifest
+++ b/xfce-extra/xfce4-screensaver/Manifest
@@ -1 +1,2 @@
 DIST xfce4-screensaver-0.1.4.tar.bz2 617922 BLAKE2B c5cdf360cb1a9c38583a52bcb2d2735d2513c26aaebf23b4be4300266b72d780a3a0d8981c14f9753592eb1f63088f3fd8fd234efb6a595cb49262adaf54aca7 SHA512 5f074eb3c34ba731d0c135c657043ee687809146be512943f0f2892e1d06806400a5ecb1278dcb47da39ded47ddd4f9020cefc917ebb502962e16e56ee3a9b6d
+DIST xfce4-screensaver-0.1.5.tar.bz2 614480 BLAKE2B fda9bcb9c806a8e3b32628405f0ffc5f391f12a4bbd949f0ddeb3dd299a9bbc7bcc6e6551ddce4b3709d2d1f0192f5e36fe064f4d779aa82ae42af4bbb148ac6 SHA512 939dd5215b76e05a6a2b32b830b323bbc45a3c5e5785db1bd78560d8cfda37a92366fda9ef8e94c9b01fc1626a03170075951a1f2d47f29939e26c5dbb3c903e

diff --git a/xfce-extra/xfce4-screensaver/xfce4-screensaver-0.1.5.ebuild b/xfce-extra/xfce4-screensaver/xfce4-screensaver-0.1.5.ebuild
new file mode 100644 (file)
index 0000000..a0e23b8
--- /dev/null
+++ b/xfce-extra/xfce4-screensaver/xfce4-screensaver-0.1.5.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Screen saver and locker (port of MATE screensaver)"
+HOMEPAGE="https://git.xfce.org/apps/xfce4-screensaver/about/"
+SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="consolekit elogind +locking opengl pam systemd"
+
+# Xrandr: optional but automagic
+RDEPEND="
+       dev-libs/dbus-glib
+       >=dev-libs/glib-2.50:2
+       >=x11-libs/gtk+-3.22:3
+       x11-libs/libICE:=
+       x11-libs/libX11:=
+       x11-libs/libXScrnSaver:=
+       x11-libs/libXext:=
+       x11-libs/libXxf86misc:=
+       x11-libs/libXxf86vm:=
+       >=x11-libs/libXrandr-1.3:=
+       >=x11-libs/libxklavier-5.2:=
+       >=xfce-base/garcon-0.5.0:=
+       >=xfce-base/libxfce4ui-4.12.1:=
+       >=xfce-base/libxfce4util-4.12.1:=
+       >=xfce-base/xfconf-4.12.1:=
+       consolekit? ( sys-auth/consolekit )
+       elogind? ( sys-auth/elogind )
+       locking? (
+               pam? ( virtual/pam )
+       )
+       opengl? ( virtual/opengl )
+       systemd? ( sys-apps/systemd:= )
+"
+DEPEND="${RDEPEND}
+       dev-util/glib-utils
+       dev-util/intltool
+       sys-apps/dbus
+       virtual/pkgconfig"
+
+src_configure() {
+       local myconf=(
+               # disable docbook for now
+               ac_cv_path_XMLTO=no
+
+               # xscreensaver dirs autodetection doesn't seem to work
+               --with-xscreensaverdir=/usr/share/xscreensaver/config
+               --with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+
+               $(use_with opengl libgl)
+               $(use_enable locking)
+               $(use_enable pam)
+               $(use_with consolekit console-kit)
+               $(use_with elogind)
+               $(use_with systemd)
+       )
+
+       if use pam; then
+               myconf+=( --with-pam-auth-type=system )
+       fi
+
+       econf "${myconf[@]}"
+}
+
+src_install() {
+       default
+
+       find "${D}" -name '*.la' -delete || die
+}