Version bump 4.0.0

Package-Manager: portage-2.2_rc67/cvs/Linux x86_64

diff --git a/dev-util/kdevelop/ChangeLog b/dev-util/kdevelop/ChangeLog
index adbbbf4ec4dbe087cd3249b9e7ed511b883b479d..bfacce034062834a36cb12fde45ce5bd1fcb2c27 100644 (file)
--- a/dev-util/kdevelop/ChangeLog
+++ b/dev-util/kdevelop/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/kdevelop
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop/ChangeLog,v 1.193 2010/04/18 23:23:04 spatz Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop/ChangeLog,v 1.194 2010/04/29 05:07:50 reavertm Exp $
+
+*kdevelop-4.0.0 (29 Apr 2010)
+
+  29 Apr 2010; Maciej Mrozowski <reavertm@gentoo.org>
+  +kdevelop-4.0.0.ebuild:
+  Version bump 4.0.0
 
 *kdevelop-3.10.2 (18 Apr 2010)
 

diff --git a/dev-util/kdevelop/kdevelop-4.0.0.ebuild b/dev-util/kdevelop/kdevelop-4.0.0.ebuild
new file mode 100644 (file)
index 0000000..e1c1b90
--- /dev/null
+++ b/dev-util/kdevelop/kdevelop-4.0.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/kdevelop/kdevelop-4.0.0.ebuild,v 1.1 2010/04/29 05:07:50 reavertm Exp $
+
+EAPI="2"
+
+if [[ ${PV} == *9999* ]]; then
+       KDEVPLATFORM_PV="9999"
+else
+       KDE_LINGUAS="ca ca@valencia da de en_GB es et fr gl it nds pt pt_BR sv tr uk zh_CN zh_TW"
+       inherit versionator
+       KDEVPLATFORM_PV="$(($(get_major_version)-3)).$(get_after_major_version)"
+fi
+
+KMNAME="extragear/sdk"
+inherit kde4-base
+
+DESCRIPTION="Integrated Development Environment for Unix, supporting KDE/Qt, C/C++ and many other languages."
+HOMEPAGE="http://www.kdevelop.org/"
+[[ ${PV} != *9999* ]] && SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2"
+KEYWORDS="~amd64 ~hppa ~x86"
+SLOT="4"
+IUSE="+cmake +cxx debug +qmake qthelp"
+
+DEPEND="
+       >=dev-util/kdevplatform-${KDEVPLATFORM_PV}
+       >=kde-base/ksysguard-${KDE_MINIMAL}
+       >=kde-base/libkworkspace-${KDE_MINIMAL}
+       qthelp? ( >=x11-libs/qt-assistant-4.4:4 )
+"
+RDEPEND="${DEPEND}
+       >=kde-base/kapptemplate-${KDE_MINIMAL}
+       cxx? ( >=sys-devel/gdb-7.0[python] )
+"
+
+src_prepare() {
+       kde4-base_src_prepare
+
+       # Remove this and the ksysguard dep after libprocessui moved into kdelibs
+       sed -i -e 's/${KDE4WORKSPACE_PROCESSUI_LIBS}/processui/g' \
+               debuggers/gdb/CMakeLists.txt \
+               || die "Failed to patch CMake files"
+}
+
+src_configure() {
+       mycmakeargs=(
+               $(cmake-utils_use_build cmake)
+               $(cmake-utils_use_build cmake cmakebuilder)
+               $(cmake-utils_use_build qmake)
+               $(cmake-utils_use_build qmake qmakebuilder)
+               $(cmake-utils_use_build qmake qmake_parser)
+               $(cmake-utils_use_build cxx cpp)
+               $(cmake-utils_use_build qthelp)
+       )
+
+       kde4-base_src_configure
+}