dev-util/pkgcheck: version bump to 0.7.2

Signed-off-by: Tim Harder <radhermit@gentoo.org>

diff --git a/dev-util/pkgcheck/Manifest b/dev-util/pkgcheck/Manifest
index 3df03262f7e87c1fcf7f059c3db7426be7f32ea3..d99f5642ea883955880901fddff2a419fdb83166 100644 (file)
--- a/dev-util/pkgcheck/Manifest
+++ b/dev-util/pkgcheck/Manifest
@@ -1 +1,2 @@
 DIST pkgcheck-0.7.1.tar.gz 212835 BLAKE2B 07fce0ed898a276ff939aec9018e02816b0abefe2a2c491ba7be8fb9616fd2351d827ae7f9248ed708a6dc1c387e3b7f30fd78ddbf8aa14b247bdec9e4925bf5 SHA512 0aaab2319d8a9c8dacf1027fd45239b11e530f213c940fcd1cda775f3e214064249c5598d586fb7bf3c0da53460de6e4d19e73ad26ec9be2bfdec645a82f78d1
+DIST pkgcheck-0.7.2.tar.gz 218204 BLAKE2B 2fffbfce7856deec3b32fe5e8d754dec39b5bb4b85c2bc06f06539916ae6c8542ff6b7997d3e2d2aef8f60ad80159c3ce10768146938844dc64e817ae993c23a SHA512 152aafb48f8a58fca72604f72a1d5a1621dd8a5d93d0a64529028c480be5e92488cbe0d7548ece4aef6b1721e1249f28103ba5bd8a9c69a85f0ba18e933df5bf

diff --git a/dev-util/pkgcheck/pkgcheck-0.7.2.ebuild b/dev-util/pkgcheck/pkgcheck-0.7.2.ebuild
new file mode 100644 (file)
index 0000000..4626c74
--- /dev/null
+++ b/dev-util/pkgcheck/pkgcheck-0.7.2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{6,7,8} )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1
+
+if [[ ${PV} == *9999 ]] ; then
+       EGIT_REPO_URI="https://github.com/pkgcore/pkgcheck.git"
+       inherit git-r3
+else
+       KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+       SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+fi
+
+DESCRIPTION="pkgcore-based QA utility"
+HOMEPAGE="https://github.com/pkgcore/pkgcheck"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="network perl test"
+RESTRICT="!test? ( test )"
+
+if [[ ${PV} == *9999 ]]; then
+       RDEPEND="
+               ~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+               ~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
+else
+       RDEPEND="
+               >=dev-python/snakeoil-0.8.5[${PYTHON_USEDEP}]
+               >=sys-apps/pkgcore-0.10.9[${PYTHON_USEDEP}]"
+fi
+RDEPEND+="
+       dev-python/chardet[${PYTHON_USEDEP}]
+       dev-python/lxml[${PYTHON_USEDEP}]
+       dev-python/pathspec[${PYTHON_USEDEP}]
+       network? ( dev-python/requests[${PYTHON_USEDEP}] )
+       perl? ( dev-perl/Gentoo-PerlMod-Version )
+"
+DEPEND="${RDEPEND}
+       dev-python/setuptools[${PYTHON_USEDEP}]
+       test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+python_test() {
+       esetup.py test
+}
+
+python_install_all() {
+       local DOCS=( AUTHORS NEWS.rst )
+       [[ ${PV} == *9999 ]] || doman man/*
+       distutils-r1_python_install_all
+}

diff --git a/dev-util/pkgcheck/pkgcheck-9999.ebuild b/dev-util/pkgcheck/pkgcheck-9999.ebuild
index b81e8708d7c042ad7cfb5dea66321254fca26f60..4626c74a350b6228c3dfbe19106877a2c2f60fb8 100644 (file)
--- a/dev-util/pkgcheck/pkgcheck-9999.ebuild
+++ b/dev-util/pkgcheck/pkgcheck-9999.ebuild
@@ -28,8 +28,8 @@ if [[ ${PV} == *9999 ]]; then
                ~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
 else
        RDEPEND="
-               >=dev-python/snakeoil-0.8.4[${PYTHON_USEDEP}]
-               >=sys-apps/pkgcore-0.10.8[${PYTHON_USEDEP}]"
+               >=dev-python/snakeoil-0.8.5[${PYTHON_USEDEP}]
+               >=sys-apps/pkgcore-0.10.9[${PYTHON_USEDEP}]"
 fi
 RDEPEND+="
        dev-python/chardet[${PYTHON_USEDEP}]