From: Tassilo Horn <tassilo@member.fsf.org>
To: notmuch@notmuchmail.org
Mail-Copies-To: never
Mail-Followup-To: notmuch@notmuchmail.org
Date: Tue, 24 Nov 2009 09:02:46 +0100
Message-ID: <87zl6cl595.fsf@thinkpad.tsdh.de>
User-Agent: Gnus/5.13 (Gnus v5.13) Emacs/23.1.50 (gnu/linux)
MIME-Version: 1.0
Content-Type: text/plain; charset=us-ascii
Subject: [notmuch] Snippet to jump to message in Gnus from notmuch-show
	buffer
Precedence: list

Hi all,

I'm a Gnus user and use notmuch mostly for searching.  When I want to
reply to a message, I need to get back to Gnus, so that my Gnus posting
styles (gcc into that group, right email address, correct signature,...)
are applied.

Therefore, I created this small snippet.  Now C-c C-c inside some
message in the *notmuch-show* buffer opens this article in a Gnus
*Summary* buffer, where I can reply to it, forward it, ...

Of course, the translation from file name to Gnus group name is
something that is different for any user.  The essence of this code is
the call to the org-gnus.el function `org-gnus-follow-link', which takes
the group name and the message-id.  It's included in Emacsen >= 23.

--8<---------------cut here---------------start------------->8---
(require 'notmuch)

(defun th-notmuch-file-to-group (file)
  "Calculate the Gnus group name from the given file name.

Example:

  IN: /home/horn/Mail/Dovecot/uni/INBOX/dbox-Mails/u.4075
  OUT: nnimap+Uni:INBOX"
  (concat "nnimap+"
          (replace-regexp-in-string 
           "^\\([^/]+\\)/" "\\1:"
           (replace-regexp-in-string 
            "/dbox-Mails/.*" ""
            (replace-regexp-in-string
             "/home/horn/Mail/Dovecot/" "" file)))))

(defun th-notmuch-goto-message-in-gnus ()
  "Open a summary buffer containing the current notmuch
article."
  (interactive)
  (let ((group (th-notmuch-file-to-group (notmuch-show-get-filename)))
        (message-id (replace-regexp-in-string
                     "^id:" "" (notmuch-show-get-message-id))))
    (message "G: %s, mid: %s" group message-id)
    (if (and group message-id)
        (org-gnus-follow-link group message-id)
      (message "Couldn't get relevant infos for switching to Gnus."))))

(define-key notmuch-show-mode-map (kbd "C-c C-c") 'th-notmuch-goto-message-in-gnus)
--8<---------------cut here---------------end--------------->8---

BTW, why does `notmuch-show-get-message-id' prefix the message-id with
"id:"?

Bye,
Tassilo