From: david@tethera.net
To: notmuch@notmuchmail.org
Date: Wed, 24 Feb 2010 08:52:00 -0400
Message-Id: <1267015920-8999-1-git-send-email-david@tethera.net>
In-Reply-To: <1261341081-26479-1-git-send-email-david@tethera.net>
References: <1261341081-26479-1-git-send-email-david@tethera.net>
Cc: David Bremner <bremner@unb.ca>
Subject: [notmuch] [PATCH v2] notmuch-query.el: new file to support access
	to the notmuch database.
Precedence: list

From: David Bremner <bremner@unb.ca>

Initially this file provides one main function
notmuch-query-get-threads, which takes a set of search terms, and
returns a parsed set of matching threads as a lisp data structure.

A set of notmuch-query-map-* functions are provided to help map
functions over the data structure.

The function notmuch-query-get-message-ids uses this machinery to get
the set of message-ids matching a query.

This patch relies on the emacs directory  patch of
<1265773528-30794-1-git-send-email-david@tethera.net>
---

 This version is rebased against the json patches that eventually made
 it into master. Oddly, no actual changes were required based on
 Carl's change of "id" to "thread".   Some trailing whitespace was
 also removed.

 emacs/Makefile.local   |    3 +-
 emacs/notmuch-query.el |   89 ++++++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 91 insertions(+), 1 deletions(-)
 create mode 100644 emacs/notmuch-query.el

diff --git a/emacs/Makefile.local b/emacs/Makefile.local
index c6ca142..6c87a60 100644
--- a/emacs/Makefile.local
+++ b/emacs/Makefile.local
@@ -1,6 +1,7 @@
 dir=emacs
 emacs_sources=                 \
-	$(dir)/notmuch.el
+	$(dir)/notmuch.el      \
+	$(dir)/notmuch-query.el
 
 emacs_bytecode=$(subst .el,.elc,$(emacs_sources))
 
diff --git a/emacs/notmuch-query.el b/emacs/notmuch-query.el
new file mode 100644
index 0000000..86230ba
--- /dev/null
+++ b/emacs/notmuch-query.el
@@ -0,0 +1,89 @@
+; notmuch.el --- run notmuch within emacs
+;
+; Copyright © David Bremner
+;
+; This file is part of Notmuch.
+;
+; Notmuch is free software: you can redistribute it and/or modify it
+; under the terms of the GNU General Public License as published by
+; the Free Software Foundation, either version 3 of the License, or
+; (at your option) any later version.
+;
+; Notmuch is distributed in the hope that it will be useful, but
+; WITHOUT ANY WARRANTY; without even the implied warranty of
+; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+; General Public License for more details.
+;
+; You should have received a copy of the GNU General Public License
+; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
+;
+; Authors: David Bremner <david@tethera.net>
+
+(require 'json)
+
+(defun notmuch-query-get-threads (search-terms &rest options)
+  "Return a list of threads of messages matching SEARCH-TERMS.
+
+A thread is a forest or list of trees. A tree is a two element
+list where the first element is a message, and the second element
+is a possibly empty forest of replies.
+"
+  (let  ((args (append '("show" "--format=json") search-terms))
+	 (json-object-type 'plist)
+	 (json-array-type 'list)
+	 (json-false 'nil))
+    (with-temp-buffer
+      (progn
+	(apply 'call-process (append (list notmuch-command nil t nil) args))
+	(goto-char (point-min))
+	(json-read)))))
+
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+;; Mapping functions across collections of messages.
+
+(defun notmuch-query-map-aux  (mapper function seq)
+  "private function to do the actual mapping and flattening"
+
+  (apply 'append
+	 (mapcar
+	   (lambda (tree)
+	     (funcall mapper fn tree))
+	   seq)))
+
+
+(defun notmuch-query-map-threads (fn threads)
+  "apply FN to every thread in  THREADS. Flatten results to a list.
+
+See the function notmuch-query-get-threads for more information."
+
+  (notmuch-query-map-aux 'notmuch-query-map-forest fn threads))
+
+
+(defun notmuch-query-map-forest (fn forest)
+  "apply function to every message in a forest. Flatten results to a list.
+
+See the function notmuch-query-get-threads for more information.
+"
+
+  (notmuch-query-map-aux 'notmuch-query-map-tree fn forest))
+
+
+(defun notmuch-query-map-tree (fn tree)
+  "Apply function FN to every message in TREE. Flatten results to a list
+
+See the function notmuch-query-get-threads for more information."
+
+  (cons (funcall fn (car tree)) (notmuch-query-map-forest fn (cadr tree))))
+
+
+;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
+;; Predefined queries
+
+(defun notmuch-query-get-message-ids (&rest search-terms)
+  "Return a list of message-ids of messages that match SEARCH-TERMS"
+
+  (notmuch-query-map-threads
+   (lambda (msg) (plist-get msg :id))
+   (notmuch-query-get-threads search-terms)))
+
+(provide 'notmuch-query)
-- 
1.6.5