git.tremily.us Git - gentoo.git/blob

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 MODULE_AUTHOR=DANBORN
   8 MODULE_VERSION=1.03
   9 inherit perl-module
  10
  11 DESCRIPTION="SpamAssassin plugin to score mail based on Google blocklists"
  12
  13 LICENSE="Apache-2.0"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86 ~ppc"
  16 IUSE="test"
  17
  18 RDEPEND="dev-perl/Net-Google-SafeBrowsing-Blocklist
  19                  dev-perl/Net-Google-SafeBrowsing-UpdateRequest
  20                  mail-filter/spamassassin"
  21 DEPEND="${RDEPEND}
  22                 test? ( dev-perl/Test-Pod )"
  23
  24 SRC_TEST="do"
  25
  26 src_install() {
  27         perl-module_src_install
  28         insinto /etc/mail/spamassassin
  29         doins "${FILESDIR}"/init_google_safebrowsing.pre
  30         doins "${FILESDIR}"/24_google_safebrowsing.cf
  31         insinto /etc/cron.d/
  32         newins "${FILESDIR}"/update_google_safebrowsing.cron update_google_safebrowsing
  33         dosbin "${FILESDIR}"/update_google_safebrowsing.sh
  34         keepdir /var/lib/spamassassin/google_safebrowsing/
  35 }
  36
  37 pkg_postinst() {
  38         if [[ -f ${ROOT}/etc/cron.d/update_google_safebrowsing.sh ]]; then
  39                 ewarn "You MUST remove ${ROOT}/etc/cron.d/update_google_safebrowsing.sh"
  40         fi
  41         elog "To use this package:"
  42         elog "1. You MUST apply for a free apikey at:"
  43         elog "   http://code.google.com/apis/safebrowsing/key_signup.html"
  44         elog "2. Place the key into /etc/mail/spamassassin/24_google_safebrowsing.cf"
  45         elog "3. Manually run the script /usr/sbin/update_google_safebrowsing.sh"
  46         elog "4. Enable the plugin by uncommenting the loadplugin entry in"
  47         elog "   /etc/mail/spamassassin/init_google_safebrowsing.pre"
  48         elog "5. Restart spamd"
  49 }