xfce-extra/xfce4-sensors-plugin/xfce4-sensors-plugin-1.3.92-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2-utils
   7
   8 DESCRIPTION="A panel plug-in for acpi, lm-sensors and hddtemp sensors"
   9 HOMEPAGE="https://goodies.xfce.org/projects/panel-plugins/xfce4-sensors-plugin"
  10 SRC_URI="https://archive.xfce.org/src/panel-plugins/${PN}/${PV%.*}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2+"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
  15 IUSE="+acpi hddtemp libnotify lm-sensors video_cards_nvidia"
  16
  17 REQUIRED_USE="|| ( hddtemp lm-sensors acpi )"
  18
  19 RDEPEND=">=x11-libs/gtk+-3.20:3=
  20         >=xfce-base/libxfce4ui-4.12:=[gtk3(+)]
  21         >=xfce-base/xfce4-panel-4.12:=
  22         hddtemp? (
  23                 app-admin/hddtemp
  24                 || (
  25                         net-analyzer/openbsd-netcat
  26                         net-analyzer/netcat
  27                 )
  28         )
  29         libnotify? ( >=x11-libs/libnotify-0.7:= )
  30         lm-sensors? ( >=sys-apps/lm-sensors-3.1.0:= )
  31         video_cards_nvidia? ( x11-drivers/nvidia-drivers[tools,static-libs] )"
  32
  33 DEPEND="${RDEPEND}
  34         dev-util/intltool
  35         virtual/pkgconfig"
  36
  37 DOCS=( AUTHORS ChangeLog NEWS NOTES README TODO )
  38
  39 src_configure() {
  40         local myconf=(
  41                 --libexecdir="${EPREFIX}"/usr/$(get_libdir)
  42                 $(use_enable lm-sensors libsensors)
  43                 $(use_enable hddtemp)
  44                 $(use_enable hddtemp netcat)
  45                 $(use_enable acpi procacpi)
  46                 $(use_enable acpi sysfsacpi)
  47                 $(use_enable video_cards_nvidia xnvctrl)
  48                 $(use_enable libnotify notification)
  49                 --disable-pathchecks
  50         )
  51
  52         econf "${myconf[@]}"
  53 }
  54
  55 src_install() {
  56         emake DESTDIR="${D}" install
  57         einstalldocs
  58         find "${D}" -name '*.la' -delete || die
  59 }
  60
  61 pkg_postinst() {
  62         gnome2_icon_cache_update
  63 }
  64
  65 pkg_postrm() {
  66         gnome2_icon_cache_update
  67 }