xfce-base/libxfce4ui/libxfce4ui-4.13.3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2-utils
   7
   8 DESCRIPTION="Unified widget and session management libs for Xfce"
   9 HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
  10 SRC_URI="mirror://xfce/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
  11
  12 LICENSE="LGPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
  15 IUSE="debug glade introspection startup-notification"
  16
  17 RDEPEND=">=dev-libs/glib-2.42:2=
  18         >=x11-libs/gtk+-2.24:2=
  19         >=x11-libs/gtk+-3.18:3=[introspection?]
  20         x11-libs/libX11:=
  21         x11-libs/libICE:=
  22         x11-libs/libSM:=
  23         >=xfce-base/libxfce4util-4.12:=[introspection?]
  24         >=xfce-base/xfconf-4.12:=
  25         glade? ( dev-util/glade:3.10= )
  26         introspection? ( dev-libs/gobject-introspection:= )
  27         startup-notification? ( x11-libs/startup-notification:= )
  28         !xfce-base/xfce-utils"
  29 DEPEND="${RDEPEND}
  30         dev-lang/perl
  31         dev-util/intltool
  32         sys-devel/gettext
  33         virtual/pkgconfig"
  34
  35 src_configure() {
  36         local myconf=(
  37                 $(use_enable introspection)
  38                 $(use_enable startup-notification)
  39                 # TODO: check revdeps and make it optional one day
  40                 --enable-gtk2
  41                 # requires deprecated glade:3 (gladeui-1.0), bug #551296
  42                 --disable-gladeui
  43                 # this one's for :3.10
  44                 $(use_enable glade gladeui2)
  45                 --with-vendor-info=Gentoo
  46         )
  47
  48         econf "${myconf[@]}"
  49 }
  50
  51 src_install() {
  52         default
  53
  54         find "${D}" -name '*.la' -delete || die
  55 }
  56
  57 pkg_postinst() {
  58         gnome2_icon_cache_update
  59 }
  60
  61 pkg_postrm() {
  62         gnome2_icon_cache_update
  63 }