x11-wm/marco/marco-1.12.1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MATE2_LA_PUNT="yes"
   7
   8 inherit mate
   9
  10 if [[ ${PV} != 9999 ]]; then
  11         KEYWORDS="amd64 ~arm x86"
  12 fi
  13
  14 DESCRIPTION="MATE default window manager"
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17
  18 IUSE="gtk3 startup-notification test xinerama"
  19
  20 RDEPEND="
  21         dev-libs/atk:0
  22         >=dev-libs/glib-2.32.10:2
  23         >=gnome-base/libgtop-2:2=
  24         gnome-extra/zenity:0
  25         x11-libs/cairo:0
  26         >=x11-libs/pango-1.2:0[X]
  27         x11-libs/gdk-pixbuf:2
  28         x11-libs/libICE:0
  29         x11-libs/libSM:0
  30         x11-libs/libX11:0
  31         >=x11-libs/libXcomposite-0.3:0
  32         x11-libs/libXcursor:0
  33         x11-libs/libXdamage:0
  34         x11-libs/libXext:0
  35         x11-libs/libXfixes:0
  36         x11-libs/libXrandr:0
  37         x11-libs/libXrender:0
  38         >=x11-libs/startup-notification-0.7:0
  39         virtual/libintl:0
  40         !gtk3? (
  41                 media-libs/libcanberra:0[gtk]
  42                 >=x11-libs/gtk+-2.24:2
  43         )
  44         gtk3? (
  45                 media-libs/libcanberra:0[gtk3]
  46                 >=x11-libs/gtk+-3.0:3
  47         )
  48         xinerama? ( x11-libs/libXinerama:0 )
  49         !!x11-wm/mate-window-manager"
  50
  51 DEPEND="${RDEPEND}
  52         app-text/yelp-tools:0
  53         >=dev-util/intltool-0.34.90:*
  54         sys-devel/gettext:*
  55         virtual/pkgconfig:*
  56         x11-proto/xextproto:0
  57         x11-proto/xproto:0
  58         test? ( app-text/docbook-xml-dtd:4.5 )
  59         xinerama? ( x11-proto/xineramaproto:0 )"
  60
  61 src_configure() {
  62         mate_src_configure \
  63                 --enable-compositor \
  64                 --enable-render \
  65                 --enable-shape \
  66                 --enable-sm \
  67                 --enable-xsync \
  68                 --with-gtk=$(usex gtk3 3.0 2.0) \
  69                 $(use_enable startup-notification) \
  70                 $(use_enable xinerama)
  71 }
  72
  73 src_install() {
  74         mate_src_install
  75         dodoc {,doc/}*.txt
  76 }