x11-wm/lumina/lumina-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit git-r3 qmake-utils
   7 DESCRIPTION="Lumina desktop environment"
   8 HOMEPAGE="https://lumina-desktop.org/"
   9 EGIT_REPO_URI="https://github.com/trueos/lumina"
  10
  11 LICENSE="BSD"
  12 SLOT="0"
  13 KEYWORDS=""
  14 IUSE="desktop-utils"
  15
  16 COMMON_DEPEND="dev-qt/qtcore:5
  17         dev-qt/qtconcurrent:5
  18         dev-qt/qtmultimedia:5[widgets]
  19         dev-qt/qtsvg:5
  20         dev-qt/qtnetwork:5
  21         dev-qt/qtwidgets:5
  22         dev-qt/qtx11extras:5
  23         dev-qt/qtgui:5
  24         dev-qt/qtdeclarative:5
  25         x11-libs/libxcb:0
  26         x11-libs/xcb-util
  27         x11-libs/xcb-util-image
  28         x11-libs/xcb-util-wm"
  29
  30 DEPEND="$COMMON_DEPEND
  31         dev-qt/linguist-tools:5"
  32
  33 RDEPEND="$COMMON_DEPEND
  34         sys-fs/inotify-tools
  35         x11-misc/numlockx
  36         x11-wm/fluxbox
  37         || ( x11-apps/xbacklight
  38         sys-power/acpilight )
  39         media-sound/alsa-utils
  40         sys-power/acpi
  41         app-admin/sysstat"
  42
  43 S="${WORKDIR}/${P/_/-}"
  44
  45 PATCHES=(
  46         "${FILESDIR}/1.2.0-desktop-files.patch"
  47 )
  48
  49 src_prepare() {
  50         default
  51
  52         if use !desktop-utils ; then
  53                 rm -rf src-qt5/desktop-utils || die
  54                 sed -e "/desktop-utils/d" -i src-qt5/src-qt5.pro || die
  55         fi
  56 }
  57
  58 src_configure() {
  59         eqmake5 PREFIX="${EPREFIX}/usr" LIBPREFIX="${EPREFIX}/usr/$(get_libdir)" \
  60                 DESTDIR="${D}" CONFIG+=WITH_I18N QMAKE_CFLAGS_ISYSTEM=
  61 }
  62
  63 src_install() {
  64         default
  65         mv "${ED%/}"/etc/luminaDesktop.conf{.dist,} || die
  66         rm "${ED%/}"/${PN}-* "${ED%/}"/start-${PN}-desktop || die
  67 }