x11-wm/dwm/dwm-6.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit savedconfig toolchain-funcs
   6
   7 DESCRIPTION="a dynamic window manager for X11"
   8 HOMEPAGE="https://dwm.suckless.org/"
   9 SRC_URI="https://dl.suckless.org/${PN}/${P}.tar.gz"
  10
  11 LICENSE="MIT"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
  14 IUSE="xinerama"
  15
  16 RDEPEND="
  17         media-libs/fontconfig
  18         x11-libs/libX11
  19         x11-libs/libXft
  20         xinerama? ( x11-libs/libXinerama )
  21 "
  22 DEPEND="
  23         ${RDEPEND}
  24         xinerama? ( x11-base/xorg-proto )
  25 "
  26
  27 src_prepare() {
  28         default
  29
  30         sed -i \
  31                 -e "s/ -Os / /" \
  32                 -e "/^\(LDFLAGS\|CFLAGS\|CPPFLAGS\)/{s| = | += |g;s|-s ||g}" \
  33                 config.mk || die
  34
  35         restore_config config.h
  36 }
  37
  38 src_compile() {
  39         if use xinerama; then
  40                 emake CC=$(tc-getCC) dwm
  41         else
  42                 emake CC=$(tc-getCC) XINERAMAFLAGS="" XINERAMALIBS="" dwm
  43         fi
  44 }
  45
  46 src_install() {
  47         emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
  48
  49         exeinto /etc/X11/Sessions
  50         newexe "${FILESDIR}"/dwm-session2 dwm
  51
  52         insinto /usr/share/xsessions
  53         doins "${FILESDIR}"/dwm.desktop
  54
  55         dodoc README
  56
  57         save_config config.h
  58 }