x11-themes/adwaita-icon-theme/adwaita-icon-theme-3.20.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="6"
   6
   7 inherit gnome2 versionator
   8
   9 DESCRIPTION="GNOME default icon theme"
  10 HOMEPAGE="https://git.gnome.org/browse/adwaita-icon-theme/"
  11
  12 SRC_URI="${SRC_URI}
  13         branding? ( http://www.mail-archive.com/tango-artists@lists.freedesktop.org/msg00043/tango-gentoo-v1.1.tar.gz )
  14 "
  15 LICENSE="
  16         || ( LGPL-3 CC-BY-SA-3.0 )
  17         branding? ( CC-Sampling-Plus-1.0 )
  18 "
  19 SLOT="0"
  20 IUSE="branding"
  21 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
  22
  23 COMMON_DEPEND="
  24         >=x11-themes/hicolor-icon-theme-0.10
  25 "
  26 RDEPEND="${COMMON_DEPEND}
  27         gnome-base/librsvg:2
  28         !<x11-themes/gnome-themes-standard-3.14
  29 "
  30 DEPEND="${COMMON_DEPEND}
  31         >=dev-util/intltool-0.40
  32         sys-devel/gettext
  33         virtual/pkgconfig
  34 "
  35 # This ebuild does not install any binaries
  36 RESTRICT="binchecks strip"
  37
  38 src_prepare() {
  39         if use branding; then
  40                 for i in 16 22 24 32 48; do
  41                         cp "${WORKDIR}"/tango-gentoo-v1.1/${i}x${i}/gentoo.png \
  42                         "${S}"/Adwaita/${i}x${i}/places/start-here.png \
  43                         || die "Copying gentoo logos failed"
  44                 done
  45         fi
  46
  47         # Install cursors in the right place used in Gentoo
  48         sed -e 's:^\(cursordir.*\)icons\(.*\):\1cursors/xorg-x11\2:' \
  49                 -i "${S}"/Makefile.am \
  50                 -i "${S}"/Makefile.in || die
  51
  52         gnome2_src_prepare
  53 }
  54
  55 src_configure() {
  56         gnome2_src_configure GTK_UPDATE_ICON_CACHE=$(type -P true)
  57 }