x11-terms/rxvt-unicode/rxvt-unicode-9.22-r3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit autotools desktop
   6
   7 DESCRIPTION="rxvt clone with xft and unicode support"
   8 HOMEPAGE="http://software.schmorp.de/pkg/rxvt-unicode.html"
   9 SRC_URI="http://dist.schmorp.de/rxvt-unicode/Attic/${P}.tar.bz2"
  10
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris"
  14 IUSE="
  15         256-color blink fading-colors +font-styles gdk-pixbuf iso14755 +mousewheel
  16         +perl startup-notification unicode3 +utmp +wtmp xft
  17 "
  18 RESTRICT="test"
  19
  20 RDEPEND="
  21         >=sys-libs/ncurses-5.7-r6:=
  22         media-libs/fontconfig
  23         x11-libs/libX11
  24         x11-libs/libXrender
  25         gdk-pixbuf? ( x11-libs/gdk-pixbuf )
  26         kernel_Darwin? ( dev-perl/Mac-Pasteboard )
  27         perl? ( dev-lang/perl:= )
  28         startup-notification? ( x11-libs/startup-notification )
  29         xft? ( x11-libs/libXft )
  30 "
  31 DEPEND="
  32         ${RDEPEND}
  33         virtual/pkgconfig
  34         x11-base/xorg-proto
  35 "
  36 PATCHES=(
  37         "${FILESDIR}"/${PN}-9.06-case-insensitive-fs.patch
  38         "${FILESDIR}"/${PN}-9.21-xsubpp.patch
  39 )
  40 DOCS=(
  41         Changes
  42         README.FAQ
  43         doc/README.xvt
  44         doc/changes.txt
  45         doc/etc/${PN}.term{cap,info}
  46         doc/rxvt-tabbed
  47 )
  48
  49 src_prepare() {
  50         default
  51
  52         # kill the rxvt-unicode terminfo file - #192083
  53         sed -i -e "/rxvt-unicode.terminfo/d" doc/Makefile.in || die "sed failed"
  54
  55         eautoreconf
  56 }
  57
  58 src_configure() {
  59         # --enable-everything goes first: the order of the arguments matters
  60         econf --enable-everything \
  61                 $(use_enable 256-color) \
  62                 $(use_enable blink text-blink) \
  63                 $(use_enable fading-colors fading) \
  64                 $(use_enable font-styles) \
  65                 $(use_enable gdk-pixbuf pixbuf) \
  66                 $(use_enable iso14755) \
  67                 $(use_enable mousewheel) \
  68                 $(use_enable perl) \
  69                 $(use_enable startup-notification) \
  70                 $(use_enable unicode3) \
  71                 $(use_enable utmp) \
  72                 $(use_enable wtmp) \
  73                 $(use_enable xft)
  74 }
  75
  76 src_compile() {
  77         default
  78
  79         sed -i \
  80                 -e 's/RXVT_BASENAME = "rxvt"/RXVT_BASENAME = "urxvt"/' \
  81                 "${S}"/doc/rxvt-tabbed || die
  82 }
  83
  84 src_install() {
  85         default
  86
  87         make_desktop_entry urxvt rxvt-unicode utilities-terminal \
  88                 "System;TerminalEmulator"
  89 }