x11-terms/kitty/kitty-0.15.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7
   8 inherit python-single-r1 toolchain-funcs xdg
   9
  10 if [[ ${PV} == "9999" ]] ; then
  11         EGIT_REPO_URI="https://github.com/kovidgoyal/kitty.git"
  12         inherit git-r3
  13 else
  14         SRC_URI="https://github.com/kovidgoyal/kitty/releases/download/v${PV}/${P}.tar.xz"
  15         KEYWORDS="~amd64 ~x86"
  16 fi
  17
  18 DESCRIPTION="A modern, hackable, featureful, OpenGL-based terminal emulator"
  19 HOMEPAGE="https://github.com/kovidgoyal/kitty"
  20
  21 LICENSE="GPL-3"
  22 SLOT="0"
  23 IUSE="debug wayland"
  24 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  25
  26 RDEPEND="
  27         ${PYTHON_DEPS}
  28         media-libs/fontconfig
  29         media-libs/freetype:2
  30         >=media-libs/harfbuzz-1.5.0:=
  31         media-libs/libcanberra
  32         media-libs/libpng:0=
  33         x11-libs/libxcb[xkb]
  34         x11-libs/libXcursor
  35         x11-libs/libXi
  36         x11-libs/libXinerama
  37         x11-libs/libxkbcommon[X]
  38         x11-libs/libXrandr
  39         sys-apps/dbus
  40         sys-libs/zlib
  41         virtual/imagemagick-tools
  42         wayland? (
  43                 dev-libs/wayland
  44                 >=dev-libs/wayland-protocols-1.17
  45         )
  46 "
  47
  48 DEPEND="${RDEPEND}
  49         media-libs/mesa[X(+)]
  50         sys-libs/ncurses
  51 "
  52
  53 BDEPEND="virtual/pkgconfig"
  54
  55 [[ ${PV} == *9999 ]] && BDEPEND+=" >=dev-python/sphinx-1.7"
  56
  57 PATCHES=(
  58         "${FILESDIR}"/${P}-flags.patch
  59         "${FILESDIR}"/${PN}-0.14.4-svg-icon.patch
  60 )
  61
  62 src_prepare() {
  63         default
  64
  65         # disable wayland as required
  66         if ! use wayland; then
  67                 sed -i "/'x11 wayland'/s/ wayland//" setup.py || die
  68         fi
  69
  70         # respect doc dir
  71         sed -i "/htmldir =/s/appname/'${PF}'/" setup.py || die
  72
  73         tc-export CC
  74 }
  75
  76 src_compile() {
  77         "${EPYTHON}" setup.py \
  78                 --verbose $(usex debug --debug "") \
  79                 --libdir-name $(get_libdir) \
  80                 linux-package || die "Failed to compile kitty."
  81 }
  82
  83 src_test() {
  84         export KITTY_CONFIG_DIRECTORY=${T}
  85         "${EPYTHON}" test.py || die
  86 }
  87
  88 src_install() {
  89         insinto /usr
  90         doins -r linux-package/*
  91         dobin linux-package/bin/kitty
  92         python_fix_shebang "${ED}"
  93 }
  94
  95 pkg_postinst() {
  96         xdg_icon_cache_update
  97 }
  98
  99 pkg_postrm() {
 100         xdg_icon_cache_update
 101 }