x11-terms/guake/guake-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_6 )
   6 DISTUTILS_SINGLE_IMPL=1
   7
   8 inherit distutils-r1 git-r3 gnome2-utils xdg-utils
   9
  10 DESCRIPTION="Drop-down terminal for GNOME"
  11 HOMEPAGE="https://github.com/Guake/guake https://pypi.org/project/Guake"
  12 EGIT_REPO_URI="https://github.com/Guake/guake.git"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS=""
  17 IUSE="utempter"
  18
  19 RDEPEND="
  20         dev-libs/glib
  21         dev-libs/keybinder:3[introspection]
  22         $(python_gen_cond_dep '
  23                 dev-python/dbus-python[${PYTHON_MULTI_USEDEP}]
  24                 dev-python/pbr[${PYTHON_MULTI_USEDEP}]
  25                 dev-python/pycairo[${PYTHON_MULTI_USEDEP}]
  26                 dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
  27         ')
  28         x11-libs/libnotify[introspection]
  29         x11-libs/libwnck:3[introspection]
  30         x11-libs/vte:2.91[introspection]
  31         utempter? ( sys-libs/libutempter )
  32 "
  33 DEPEND="
  34         ${RDEPEND}
  35         gnome-base/gsettings-desktop-schemas
  36         sys-devel/gettext
  37         sys-devel/make
  38 "
  39
  40 PATCHES=(
  41         "${FILESDIR}"/${PN}-3.3.2-paths.patch
  42 )
  43
  44 python_compile_all() {
  45         emake prepare-install PREFIX=/usr
  46         emake generate-paths PREFIX=/usr DATA_DIR='$(datadir)/guake' DEV_SCHEMA_DIR='$(gsettingsschemadir)'
  47         default
  48 }
  49
  50 python_install_all() {
  51         emake install-schemas install-locale PREFIX=/usr DESTDIR="${D}"
  52         distutils-r1_python_install_all
  53 }
  54
  55 pkg_postinst() {
  56         gnome2_schemas_update
  57         xdg_desktop_database_update
  58 }
  59
  60 pkg_postrm() {
  61         gnome2_schemas_update
  62         xdg_desktop_database_update
  63 }