x11-terms/guake/guake-3.6.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_6 )
   6 DISTUTILS_SINGLE_IMPL=1
   7
   8 inherit distutils-r1 gnome2-utils xdg-utils
   9
  10 DESCRIPTION="Drop-down terminal for GNOME"
  11 HOMEPAGE="https://github.com/Guake/guake https://pypi.org/project/Guake"
  12 SRC_URI="mirror://pypi/G/${PN^}/${P^}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~arm ~x86"
  17 IUSE="utempter"
  18
  19 RDEPEND="
  20         dev-libs/glib
  21         dev-libs/keybinder:3[introspection]
  22         dev-python/dbus-python[${PYTHON_USEDEP}]
  23         dev-python/pbr[${PYTHON_USEDEP}]
  24         dev-python/pycairo[${PYTHON_USEDEP}]
  25         dev-python/pygobject:3[${PYTHON_USEDEP}]
  26         x11-libs/libnotify[introspection]
  27         x11-libs/libwnck:3[introspection]
  28         x11-libs/vte:2.91[introspection]
  29         utempter? ( sys-libs/libutempter )
  30 "
  31 DEPEND="
  32         ${RDEPEND}
  33         dev-python/setuptools[${PYTHON_USEDEP}]
  34         gnome-base/gsettings-desktop-schemas
  35         sys-devel/gettext
  36         sys-devel/make
  37 "
  38
  39 PATCHES=(
  40         "${FILESDIR}"/${PN}-3.3.2-paths.patch
  41 )
  42 S=${WORKDIR}/${P^}
  43
  44 pkg_setup() {
  45         GUAKE_SCHEMA_DIR="${EROOT}"/usr/share/glib-2.0/schemas
  46         python-single-r1_pkg_setup
  47 }
  48
  49 src_prepare() {
  50         default
  51         sed -i -e '/^SCHEMA_DIR/s|get_default_schema_dir()|"'"${GUAKE_SCHEMA_DIR}"'"|g' ${PN}/paths.py || die
  52 }
  53
  54 python_compile_all() {
  55         emake prepare-install prefix=/usr
  56         emake generate-paths prefix=/usr DATA_DIR='$(datadir)/guake' DEV_SCHEMA_DIR='$(gsettingsschemadir)'
  57         default
  58 }
  59
  60 python_install_all() {
  61         emake install-schemas install-locale prefix=/usr DESTDIR="${D}"
  62         distutils-r1_python_install_all
  63 }
  64
  65 pkg_postinst() {
  66         gnome2_schemas_update
  67         xdg_desktop_database_update
  68 }
  69
  70 pkg_postrm() {
  71         gnome2_schemas_update
  72         xdg_desktop_database_update
  73 }