x11-terms/guake/guake-3.6.1-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python3_6 )
   6 DISTUTILS_SINGLE_IMPL=1
   7
   8 inherit distutils-r1 gnome2-utils xdg-utils
   9
  10 DESCRIPTION="Drop-down terminal for GNOME"
  11 HOMEPAGE="https://github.com/Guake/guake https://pypi.org/project/Guake"
  12 SRC_URI="mirror://pypi/G/${PN^}/${P^}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~arm ~x86"
  17 IUSE="utempter"
  18
  19 RDEPEND="
  20         dev-libs/glib
  21         dev-libs/keybinder:3[introspection]
  22         dev-python/dbus-python[${PYTHON_USEDEP}]
  23         dev-python/pbr[${PYTHON_USEDEP}]
  24         dev-python/pycairo[${PYTHON_USEDEP}]
  25         dev-python/pygobject:3[${PYTHON_USEDEP}]
  26         x11-libs/libnotify[introspection]
  27         x11-libs/libwnck:3[introspection]
  28         x11-libs/vte:2.91[introspection]
  29         utempter? ( sys-libs/libutempter )
  30 "
  31 DEPEND="
  32         ${RDEPEND}
  33         dev-python/setuptools[${PYTHON_USEDEP}]
  34         gnome-base/gsettings-desktop-schemas
  35         sys-devel/gettext
  36         sys-devel/make
  37 "
  38
  39 PATCHES=(
  40         "${FILESDIR}"/${PN}-3.3.2-paths.patch
  41         "${FILESDIR}"/${PN}-3.4.0-paths.patch
  42 )
  43 S=${WORKDIR}/${P^}
  44
  45 python_compile_all() {
  46         emake prepare-install prefix=/usr
  47         emake generate-paths prefix=/usr DATA_DIR='$(datadir)/guake' DEV_SCHEMA_DIR='$(gsettingsschemadir)'
  48         default
  49 }
  50
  51 python_install_all() {
  52         emake install-schemas install-locale prefix=/usr DESTDIR="${D}"
  53         distutils-r1_python_install_all
  54 }
  55
  56 pkg_postinst() {
  57         gnome2_schemas_update
  58         xdg_desktop_database_update
  59 }
  60
  61 pkg_postrm() {
  62         gnome2_schemas_update
  63         xdg_desktop_database_update
  64 }