x11-terms/eterm/eterm-0.9.6-r2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 DESCRIPTION="A vt102 terminal emulator for X"
   7 HOMEPAGE="http://www.eterm.org/"
   8 SRC_URI="
   9         http://www.eterm.org/download/${P^}.tar.gz
  10         !minimal? ( http://www.eterm.org/download/Eterm-bg-${PV}.tar.gz )"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="alpha amd64 arm ~hppa ia64 ~mips ppc ppc64 sh sparc x86 ~amd64-linux ~ppc-macos ~x86-macos"
  15 IUSE="escreen minimal cpu_flags_x86_mmx cpu_flags_x86_sse2 unicode +utempter"
  16
  17 RDEPEND="
  18         x11-libs/libX11
  19         x11-libs/libXt
  20         x11-libs/libICE
  21         x11-libs/libSM
  22         x11-libs/libast
  23         media-libs/imlib2[X]
  24         media-fonts/font-misc-misc
  25         escreen? ( app-misc/screen )
  26 "
  27 DEPEND="${RDEPEND}"
  28
  29 DOCS=( ChangeLog README ReleaseNotes bg/README.backgrounds )
  30 PATCHES=( "${FILESDIR}"/${P}-asm-gnu-stack.patch )
  31
  32 S=${WORKDIR}/${P^}
  33
  34 src_unpack() {
  35         unpack ${P^}.tar.gz
  36         cd "${S}" || die
  37         use minimal || unpack Eterm-bg-${PV}.tar.gz
  38 }
  39
  40 src_configure() {
  41         export TIC="true"
  42         econf \
  43                 --disable-static \
  44                 $(use_enable escreen) \
  45                 --with-imlib \
  46                 --enable-trans \
  47                 $(use_enable cpu_flags_x86_mmx mmx) \
  48                 $(use_enable cpu_flags_x86_sse2 sse2) \
  49                 $(use_enable unicode multi-charset) \
  50                 $(use_enable utempter utmp) \
  51                 --with-delete=execute \
  52                 --with-backspace=auto
  53 }
  54
  55 src_install() {
  56         use escreen && DOCS+=( doc/README.Escreen )
  57         default
  58         # We don't install headers to link against this library
  59         rm -f "${ED%/}"/usr/*/libEterm.{so,la} || die
  60 }