x11-plugins/wmswallow/wmswallow-0.6.1-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic toolchain-funcs
   7
   8 DESCRIPTION="A dock applet to make any application dockable"
   9 HOMEPAGE="https://www.dockapps.net/wmswallow"
  10 SRC_URI="https://www.dockapps.net/download/${PN}.tar.Z -> ${P}.tar.Z"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86"
  15 IUSE=""
  16
  17 RDEPEND="
  18         x11-libs/libX11
  19         x11-libs/libXext"
  20 DEPEND="${RDEPEND}
  21         x11-base/xorg-proto"
  22 BDEPEND="virtual/pkgconfig"
  23
  24 S="${WORKDIR}/${PN}"
  25 PATCHES=( "${FILESDIR}"/${P}-format-security.patch )
  26
  27 src_prepare() {
  28         default
  29
  30         # the Makefile is a mess, just
  31         # rely on implicit rules instead
  32         rm Makefile || die
  33 }
  34
  35 src_configure() {
  36         tc-export CC
  37         append-cppflags $($(tc-getPKG_CONFIG) --cflags x11 xext)
  38         export LDLIBS="$($(tc-getPKG_CONFIG) --libs x11 xext)"
  39 }
  40
  41 src_compile() {
  42         emake wmswallow
  43 }
  44
  45 src_install() {
  46         dobin wmswallow
  47         dodoc CHANGELOG README todo
  48 }