x11-plugins/wmsound/wmsound-0.9.5.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=4
   6 inherit eutils multilib toolchain-funcs
   7
   8 DESCRIPTION="WindowMaker sound server"
   9 HOMEPAGE="http://largo.windowmaker.org/"
  10 SRC_URI="http://largo.windowmaker.org/files/${P}.tar.gz"
  11
  12 RDEPEND="media-sound/wmsound-data
  13         x11-libs/libproplist
  14         x11-wm/windowmaker"
  15 DEPEND="${RDEPEND}
  16         x11-misc/gccmakedep
  17         x11-misc/imake"
  18
  19 LICENSE="GPL-2"
  20 SLOT="0"
  21 KEYWORDS="~ppc x86"
  22 IUSE=""
  23
  24 src_prepare() {
  25         epatch \
  26                 "${FILESDIR}"/${PN}-config.patch \
  27                 "${FILESDIR}"/${PN}-ComplexProgramTargetNoMan.patch
  28
  29         # Fix building with -Wl,--as-needed
  30         sed -i \
  31                 -e 's:-lPropList $(WMSOUNDLIB):$(WMSOUNDLIB) -lPropList:' \
  32                 src/Imakefile || die
  33         sed -i \
  34                 -e 's:-lPropList $(XLIB) $(WMSOUNDLIB):$(WMSOUNDLIB) -lPropList $(XLIB):' \
  35                 utils/Imakefile || die
  36 }
  37
  38 src_compile() {
  39         xmkmf -a || die
  40         emake CC="$(tc-getCC)" CDEBUGFLAGS="${CFLAGS}" LDOPTIONS="${LDFLAGS}"
  41 }
  42
  43 src_install() {
  44         emake PREFIX="${D}/usr" USRLIBDIR="${D}/usr/$(get_libdir)" install
  45         dodoc AUTHORS BUGS ChangeLog
  46 }