x11-plugins/wmmaiload/wmmaiload-2.2.1-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit eutils toolchain-funcs
   6
   7 DESCRIPTION="dockapp that monitors one or more mailboxes"
   8 HOMEPAGE="http://tnemeth.free.fr/projets/dockapps.html"
   9 SRC_URI="http://tnemeth.free.fr/projets/programmes/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="amd64 ppc ~ppc64 sparc x86"
  14 IUSE=""
  15
  16 RDEPEND="x11-libs/gtk+:2
  17         x11-libs/libXpm"
  18 DEPEND="${RDEPEND}
  19         virtual/pkgconfig"
  20
  21 src_prepare() {
  22         epatch \
  23                 "${FILESDIR}"/${P}-gtk.patch \
  24                 "${FILESDIR}"/${P}-checkthread.patch
  25         sed -i -e "s/-lssl/\0 -lcrypto/" wmmaiload/Init.make || die "sed failed"
  26 }
  27
  28 src_configure() {
  29         # The ./configure script is not autoconf based, therefore don't use econf:
  30         ./configure -p /usr || die
  31 }
  32
  33 src_compile() {
  34         emake \
  35                 CC="$(tc-getCC)" \
  36                 CFLAGS="${CFLAGS}" \
  37                 DEBUG_LDFLAGS="" \
  38                 LDFLAGS="${LDFLAGS}" \
  39                 DEBUG_CFLAGS=""
  40 }
  41
  42 src_install() {
  43         dobin ${PN}/${PN} ${PN}-config/${PN}-config
  44         doman doc/*.1
  45         dodoc AUTHORS ChangeLog FAQ NEWS README THANKS TODO doc/sample.${PN}rc
  46 }