x11-plugins/gkrellweather/gkrellweather-2.0.8-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit flag-o-matic gkrellm-plugin toolchain-funcs
   7
   8 DESCRIPTION="GKrellM2 Plugin that monitors a METAR station and displays weatherinfo"
   9 HOMEPAGE="https://sites.google.com/site/makovick/gkrellm-plugins"
  10 SRC_URI="https://sites.google.com/site/makovick/projects/${P}.tgz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="2"
  14 KEYWORDS="~alpha amd64 ~ppc ~sparc x86"
  15 IUSE=""
  16
  17 RDEPEND="
  18         app-admin/gkrellm:2[X]
  19         dev-lang/perl
  20         net-misc/wget
  21         x11-libs/gtk+:2"
  22 DEPEND="
  23         ${RDEPEND}
  24         virtual/pkgconfig"
  25
  26 PATCHES=(
  27         "${FILESDIR}"/${P}-Respect-LDFLAGS.patch
  28         "${FILESDIR}"/${P}-Move-GrabWeather.patch
  29         "${FILESDIR}"/${P}-update-locations.patch
  30 )
  31
  32 src_configure() {
  33         append-cflags $($(tc-getPKG_CONFIG) --cflags gtk+-2.0)
  34         append-flags -fPIC
  35 }
  36
  37 src_compile() {
  38         emake PREFIX="${EPREFIX}"/usr CC="$(tc-getCC)" CFLAGS="${CFLAGS}"
  39 }
  40
  41 src_install() {
  42         gkrellm-plugin_src_install
  43
  44         exeinto /usr/libexec/gkrellweather
  45         doexe GrabWeather
  46 }