x11-plugins/gkrellstock/gkrellstock-0.5.1-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit flag-o-matic gkrellm-plugin toolchain-funcs
   7
   8 DESCRIPTION="Get Stock quotes plugin for Gkrellm2"
   9 HOMEPAGE="http://gkrellstock.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/gkrellstock/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="2"
  14 KEYWORDS="amd64 ~ppc x86"
  15 IUSE=""
  16
  17 RDEPEND="
  18         app-admin/gkrellm:2[X]
  19         dev-libs/glib:2
  20         x11-libs/gtk+:2
  21         dev-perl/libwww-perl
  22         dev-perl/Finance-Quote"
  23 DEPEND="${RDEPEND}
  24         virtual/pkgconfig"
  25
  26 S="${WORKDIR}/${P/s/S}"
  27 PATCHES=( "${FILESDIR}"/${PN}-0.5-ldflags.patch )
  28
  29 src_configure() {
  30         append-cppflags $($(tc-getPKG_CONFIG) --cflags gtk+-2.0)
  31         append-flags -fPIC
  32 }
  33
  34 src_compile() {
  35         emake CC=$(tc-getCC)
  36 }
  37
  38 src_install() {
  39         gkrellm-plugin_src_install
  40         dobin GetQuote2
  41 }