x11-misc/zim/zim-0.72.1-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_6 )
   6 PYTHON_REQ_USE="sqlite"
   7 DISTUTILS_SINGLE_IMPL=1
   8 inherit xdg-utils distutils-r1 virtualx
   9
  10 DESCRIPTION="A desktop wiki"
  11 HOMEPAGE="
  12         https://zim-wiki.org/
  13         https://github.com/zim-desktop-wiki/zim-desktop-wiki
  14 "
  15 SRC_URI="https://github.com/${PN}-desktop-wiki/${PN}-desktop-wiki/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
  16
  17 LICENSE="BSD GPL-2+"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 RESTRICT="test"
  21
  22 RDEPEND="
  23         $(python_gen_cond_dep '
  24                 dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
  25                 dev-python/pyxdg[${PYTHON_MULTI_USEDEP}]
  26         ')
  27         x11-libs/gtk+:3[introspection]
  28         x11-misc/xdg-utils
  29 "
  30 DEPEND="
  31         ${RDEPEND}
  32 "
  33 DOCS=( CHANGELOG.md CONTRIBUTING.md PLUGIN_WRITING.md README.md )
  34 PATCHES=( "${FILESDIR}"/${PN}-0.60-remove-ubuntu-theme.patch )
  35 S=${WORKDIR}/${PN}-desktop-wiki-${PV/_/-}
  36
  37 python_prepare_all() {
  38         sed -i -e "s/'USER'/'LOGNAME'/g" zim/__init__.py zim/fs.py || die
  39
  40         if [[ ${LINGUAS} ]]; then
  41                 local lingua
  42                 for lingua in translations/*.po; do
  43                         lingua=${lingua/.po}
  44                         lingua=${lingua/translations\/}
  45                         has ${lingua} ${LINGUAS} || \
  46                                 { rm translations/${lingua}.po || die; }
  47                 done
  48         fi
  49
  50         distutils-r1_python_prepare_all
  51 }
  52
  53 python_install() {
  54         distutils-r1_python_install
  55 }
  56
  57 pkg_postinst() {
  58         xdg_desktop_database_update
  59         xdg_icon_cache_update
  60         xdg_mimeinfo_database_update
  61         if ! has_version ${CATEGORY}/${PN}; then
  62                 elog "Please install these packages for additional functionality"
  63                 elog "    dev-lang/R"
  64                 elog "    dev-python/gtkspell-python"
  65                 elog "    dev-vcs/bzr"
  66                 elog "    media-gfx/graphviz"
  67                 elog "    media-gfx/imagemagick"
  68                 elog "    media-gfx/scrot"
  69                 elog "    media-sound/lilypond"
  70                 elog "    sci-visualization/gnuplot"
  71                 elog "    virtual/latex-base app-text/dvipng"
  72         fi
  73 }
  74
  75 pkg_postrm() {
  76         xdg_desktop_database_update
  77         xdg_icon_cache_update
  78         xdg_mimeinfo_database_update
  79 }