x11-misc/xxkb/xxkb-1.11.1-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit multilib toolchain-funcs
   6
   7 DESCRIPTION="eXtended XKB - assign different keymaps to different windows"
   8 HOMEPAGE="https://sourceforge.net/projects/xxkb/"
   9 SRC_URI="
  10         mirror://sourceforge/${PN}/${P}-src.tar.gz
  11         svg? ( https://dev.gentoo.org/~jer/${PN}-flags.tar.bz2 )
  12 "
  13
  14 LICENSE="Artistic-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~ppc ~x86"
  17 IUSE="svg"
  18
  19 RDEPEND="
  20         x11-libs/libX11
  21         x11-libs/libXpm
  22         x11-libs/libXt
  23         svg? (
  24                 dev-libs/glib:2
  25                 gnome-base/librsvg:2
  26                 x11-libs/gtk+:2
  27         )
  28 "
  29 DEPEND="
  30         ${RDEPEND}
  31         app-text/rman
  32         svg? ( virtual/pkgconfig )
  33         x11-misc/imake
  34 "
  35
  36 src_prepare() {
  37         if use svg; then
  38                 mv "${WORKDIR}"/flags . || die
  39                 eapply "${FILESDIR}"/svg-flags.patch
  40                 eapply "${FILESDIR}"/svg-appdefaults.patch
  41         fi
  42
  43         eapply "${FILESDIR}"/missing_init.patch
  44
  45         default
  46 }
  47
  48 src_configure() {
  49         xmkmf $(usex svg -DWITH_SVG_SUPPORT '') || die
  50 }
  51
  52 src_compile() {
  53         emake \
  54                 CC="$(tc-getCC)" \
  55                 CDEBUGFLAGS="${CFLAGS}" \
  56                 EXTRA_LIBRARIES="-lXext" \
  57                 LOCAL_LDFLAGS="${LDFLAGS}" \
  58                 PIXMAPDIR=/usr/share/xxkb \
  59                 PROJECTROOT=/usr
  60 }
  61
  62 src_install() {
  63         local myopts
  64         if use svg; then
  65                 myopts="PIXMAPS=flags/de.svg flags/pl.svg flags/il.svg flags/by.svg \
  66                 flags/ua.svg flags/su.svg flags/ru.svg flags/bg.svg flags/en.svg"
  67         else
  68                 myopts="FOOBAR=buzz"
  69         fi
  70
  71         emake "${myopts}"  DESTDIR="${D}" install
  72         rm -r "${D}"/usr/$(get_libdir)/X11/app-defaults || die
  73
  74         emake DESTDIR="${D}" install.man
  75
  76         insinto /usr/share/xxkb
  77         use svg || doins "${FILESDIR}"/*.xpm
  78         dodoc README* CHANGES*
  79 }