x11-misc/xwit/xwit-3.4_p15.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit toolchain-funcs
   6
   7 DESCRIPTION="A collection of simple routines to call some of those X11 functions"
   8 HOMEPAGE="https://tracker.debian.org/pkg/xwit"
   9 SRC_URI="
  10         mirror://debian/pool/main/x/${PN}/${PN}_${PV/_p*/}.orig.tar.gz
  11         mirror://debian/pool/main/x/${PN}/${PN}_${PV/_p/-}.debian.tar.gz
  12 "
  13
  14 LICENSE="public-domain HPND"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~ppc x86"
  17 IUSE=""
  18
  19 RDEPEND="x11-libs/libX11"
  20 DEPEND="${RDEPEND}
  21         x11-base/xorg-proto"
  22
  23 S=${WORKDIR}/${P/_p*/}.orig
  24
  25 PATCHES=( "${WORKDIR}"/debian/patches )
  26
  27 src_prepare() {
  28         default
  29         sed -i \
  30                 -e 's|gcc|${CC}|g' \
  31                 Makefile || die
  32         tc-export CC
  33 }
  34
  35 src_install() {
  36         dobin xwit
  37         newman xwit.man xwit.1
  38         einstalldocs
  39 }